From 5b705e3cdec52d7932b20b791d0f7e39b7b82e0f Mon Sep 17 00:00:00 2001
From: Peder Bergebakken Sundt <pbsds@hotmail.com>
Date: Sun, 20 Apr 2025 15:45:23 +0200
Subject: [PATCH] python3Packages.embreex: init at 2.17.7.post6

https://github.com/trimesh/embreex/
---
 .../python-modules/embreex/default.nix        | 72 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 74 insertions(+)
 create mode 100644 pkgs/development/python-modules/embreex/default.nix

diff --git a/pkgs/development/python-modules/embreex/default.nix b/pkgs/development/python-modules/embreex/default.nix
new file mode 100644
index 000000000000..38b2904a2cbf
--- /dev/null
+++ b/pkgs/development/python-modules/embreex/default.nix
@@ -0,0 +1,72 @@
+{
+  lib,
+  fetchFromGitHub,
+  fetchpatch,
+  buildPythonPackage,
+  embree2,
+  cython,
+  numpy,
+  setuptools,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "embreex";
+  version = "2.17.7.post6";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "trimesh";
+    repo = "embreex";
+    tag = version;
+    hash = "sha256-iLIfhngorSFOdkOvlCAJQXGQrVuRfBSDGzvjXOlQuHk=";
+  };
+
+  patches = [
+    # https://github.com/trimesh/embreex/pull/7
+    (fetchpatch {
+      name = "fix-use-after-free.patch";
+      url = "https://github.com/trimesh/embreex/commit/c6b047285419f8986fae962e2734a01522be7ef7.patch";
+      hash = "sha256-s8x2vsqbsIR3aoNUDrYs2vQttuNY8lLJ6TC7H8FMRyQ=";
+    })
+  ];
+
+  build-system = [
+    setuptools
+    numpy
+    cython
+  ];
+
+  dependencies = [
+    numpy
+  ];
+
+  buildInputs = [
+    embree2
+    embree2.tbb
+  ];
+
+  pythonImportsCheck = [
+    "embreex"
+    "embreex.mesh_construction"
+    "embreex.rtcore"
+    "embreex.rtcore_scene"
+    "embreex.triangles"
+  ];
+
+  preCheck = ''
+    # conflicts with $out
+    rm -rf embreex/
+  '';
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  meta = {
+    description = "Maintained PyEmbree fork, wrapper for Embree v2";
+    homepage = "https://github.com/trimesh/embreex";
+    changelog = "https://github.com/trimesh/embreex/releases/tag/${src.tag}";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ pbsds ];
+    inherit (embree2.meta) platforms;
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 6a6a77d1ea23..0fe2cd819c26 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -4395,6 +4395,8 @@ self: super: with self; {
 
   embrace = callPackage ../development/python-modules/embrace { };
 
+  embreex = callPackage ../development/python-modules/embreex { };
+
   emcee = callPackage ../development/python-modules/emcee { };
 
   emoji = callPackage ../development/python-modules/emoji { };