From 71a463d7237625e3ca570a24aeb58d0c72089dac Mon Sep 17 00:00:00 2001
From: Andres Vargas <avargas@intertalksystems.com>
Date: Thu, 5 Mar 2026 22:48:37 -0400
Subject: [PATCH 1/2] maintainers: add zodman

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 3fb6c89bf258..27f4beb6789c 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -30096,6 +30096,12 @@
     githubId = 873857;
     name = "Zack Newman";
   };
+  zodman = {
+    github = "zodman";
+    githubId = 44167;
+    name = "Andres Vargas";
+    email = "zodman@gmail.com";
+  };
   zoedsoupe = {
     github = "zoedsoupe";
     githubId = 44469426;

From e2607465548ec59d83e14f9836ac6c08f90594ea Mon Sep 17 00:00:00 2001
From: Andres Vargas <avargas@intertalksystems.com>
Date: Thu, 5 Mar 2026 22:48:52 -0400
Subject: [PATCH 2/2] weechat-matrix-rs: init at 0-unstable-2025-10-09

---
 pkgs/by-name/we/weechat-matrix-rs/package.nix | 61 +++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 pkgs/by-name/we/weechat-matrix-rs/package.nix

diff --git a/pkgs/by-name/we/weechat-matrix-rs/package.nix b/pkgs/by-name/we/weechat-matrix-rs/package.nix
new file mode 100644
index 000000000000..0baaef3fe0eb
--- /dev/null
+++ b/pkgs/by-name/we/weechat-matrix-rs/package.nix
@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  pkg-config,
+  weechat,
+  openssl,
+  sqlite,
+  runCommand,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "weechat-matrix-rs";
+  version = "0-unstable-2025-10-09";
+  src = fetchFromGitHub {
+    owner = "poljar";
+    repo = "weechat-matrix-rs";
+    rev = "4cc5777b630ba4d6a9c964248531f283178a4717";
+    hash = "sha256-CF4xDoRYey9F8/XSW/euNb8IjZXyP6k0Nj61shsmyEo=";
+  };
+  cargoHash = "sha256-jAlBCmLJfWWAUHd3ySB930iqAVXMh6ueba7xS///Rt0=";
+  nativeBuildInputs = [
+    pkg-config
+    rustPlatform.bindgenHook
+  ];
+  buildInputs = [
+    weechat
+    openssl
+    sqlite
+  ];
+  postInstall = ''
+    mkdir -p $out/lib/weechat/plugins
+    mv $out/lib/libmatrix${stdenv.hostPlatform.extensions.sharedLibrary} $out/lib/weechat/plugins/matrix${stdenv.hostPlatform.extensions.sharedLibrary}
+  '';
+  passthru.tests.load-plugin =
+    runCommand "${finalAttrs.pname}-test-load"
+      {
+        nativeBuildInputs = [ weechat ];
+      }
+      ''
+        weechat -t -d "$(mktemp -d)" \
+         --run-command "/plugin load ${finalAttrs.finalPackage}/lib/weechat/plugins/matrix${stdenv.hostPlatform.extensions.sharedLibrary} ; /quit" \
+         2>&1 | tee log
+        if grep -q 'Plugin "matrix" loaded' log; then
+          echo "Check passed: matrix plugin loaded into WeeChat."
+          touch $out
+        else
+          echo "Check failed: 'matrix' not found in WeeChat output."
+          exit 1
+        fi
+      '';
+  meta = {
+    description = "Rust plugin for WeeChat to communicate over Matrix";
+    homepage = "https://github.com/poljar/weechat-matrix-rs";
+    license = lib.licenses.isc;
+    maintainers = with lib.maintainers; [ zodman ];
+    platforms = lib.platforms.unix;
+  };
+
+})