From 52ef4abcc13dc75307113ebf18afb4c8121e295b Mon Sep 17 00:00:00 2001
From: Ryan Omasta <git@ryand.ca>
Date: Mon, 18 Aug 2025 00:50:30 -0600
Subject: [PATCH] lazyhetzner: init at 0.0.4

---
 pkgs/by-name/la/lazyhetzner/package.nix | 55 +++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 pkgs/by-name/la/lazyhetzner/package.nix

diff --git a/pkgs/by-name/la/lazyhetzner/package.nix b/pkgs/by-name/la/lazyhetzner/package.nix
new file mode 100644
index 000000000000..e6cb5b746d7e
--- /dev/null
+++ b/pkgs/by-name/la/lazyhetzner/package.nix
@@ -0,0 +1,55 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+
+  versionCheckHook,
+  nix-update-script,
+}:
+buildGoModule (finalAttrs: {
+  pname = "lazyhetzner";
+  version = "0.0.4";
+
+  src = fetchFromGitHub {
+    owner = "grammeaway";
+    repo = "lazyhetzner";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-MPPe4Epr77aqAFOeDGj4lTAauR489hVqGz8uiIqdyW8=";
+
+    leaveDotGit = true;
+    postFetch = ''
+      cd "$out"
+      git rev-parse HEAD > $out/COMMIT
+      date -u -d "@$(git log -1 --pretty=%ct)" "+%Y-%m-%dT%H:%M:%SZ" > $out/SOURCE_DATE_EPOCH
+      find "$out" -name .git -print0 | xargs -0 rm -rf
+    '';
+  };
+
+  vendorHash = "sha256-g+HWDhMNrPUsszmosClthEHS60Cp7zjt+50Jt9zqfTE=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/grammeaway/lazyhetzner/cmd.version=v${finalAttrs.version}"
+  ];
+
+  preBuild = ''
+    ldflags+=" -X github.com/grammeaway/lazyhetzner/cmd.commit=$(cat COMMIT)"
+    ldflags+=" -X github.com/grammeaway/lazyhetzner/cmd.date=$(cat SOURCE_DATE_EPOCH)"
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "TUI for managing Hetzner Cloud resources";
+    homepage = "https://github.com/grammeaway/lazyhetzner";
+    changelog = "https://github.com/grammeaway/lazyhetzner/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ ryand56 ];
+    mainProgram = "lazyhetzner";
+  };
+})