From 374c2c9a12e82ee5b8971ac159a475b637735c7b Mon Sep 17 00:00:00 2001
From: David Wronek <david.wronek@mainlining.org>
Date: Tue, 7 Oct 2025 11:50:43 +0200
Subject: [PATCH] pxa-mkbootimg: init at 2022.11.09

Signed-off-by: David Wronek <david.wronek@mainlining.org>
---
 pkgs/by-name/px/pxa-mkbootimg/package.nix | 40 +++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 pkgs/by-name/px/pxa-mkbootimg/package.nix

diff --git a/pkgs/by-name/px/pxa-mkbootimg/package.nix b/pkgs/by-name/px/pxa-mkbootimg/package.nix
new file mode 100644
index 000000000000..5d0f032a7274
--- /dev/null
+++ b/pkgs/by-name/px/pxa-mkbootimg/package.nix
@@ -0,0 +1,40 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "pxa-mkbootimg";
+  version = "2022.11.09";
+
+  src = fetchFromGitHub {
+    owner = "osm0sis";
+    repo = "pxa-mkbootimg";
+    rev = finalAttrs.version;
+    hash = "sha256-CZxtTPUlbUNsYTdNK0UYhlU45rYy4ToODE00MGlOPb0=";
+  };
+
+  strictDeps = true;
+
+  env.NIX_CFLAGS_COMPILE = toString (
+    lib.optional stdenv.cc.isGNU [
+      # Required with newer GCC
+      "-Wno-error=stringop-overflow"
+    ]
+  );
+
+  # Upstream has an install target, but doesn't install all required binaries
+  installPhase = ''
+    runHook preInstall
+    install -Dm555 -t $out/bin {pxa-mkbootimg,pxa-unpackbootimg,pxa1088-dtbtool,pxa1908-dtbtool}
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://github.com/osm0sis/pxa-mkbootimg";
+    description = "Boot image tool variants for the Marvell PXA1088 and PXA1908 boards";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ ungeskriptet ];
+    mainProgram = "pxa-mkbootimg";
+  };
+})