From fc958cc14689617075e777abaae0a87085dd07af Mon Sep 17 00:00:00 2001
From: Peder Bergebakken Sundt <pbsds@hotmail.com>
Date: Sat, 28 Sep 2024 01:08:06 +0200
Subject: [PATCH] python312Packages.cgal: init at 5.6.1.post202403291426

---
 .../python-modules/cgal/default.nix           | 89 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  4 +
 2 files changed, 93 insertions(+)
 create mode 100644 pkgs/development/python-modules/cgal/default.nix

diff --git a/pkgs/development/python-modules/cgal/default.nix b/pkgs/development/python-modules/cgal/default.nix
new file mode 100644
index 000000000000..e66d56879f1a
--- /dev/null
+++ b/pkgs/development/python-modules/cgal/default.nix
@@ -0,0 +1,89 @@
+{
+  lib,
+  stdenv,
+  python,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  boost,
+  cgal,
+  cmake,
+  gmp,
+  tbb,
+  LAStools,
+  eigen,
+  mpfr,
+  numpy,
+  swig,
+  zlib,
+  withLAS ? false, # unfree
+}:
+
+buildPythonPackage rec {
+  pname = "cgal";
+  version = "5.6.1.post202403291426";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "CGAL";
+    repo = "cgal-swig-bindings";
+    rev = "v${version}";
+    hash = "sha256-EcvS1TWL3uGCE1G8Lbfiu/AzifMdUSei+z91bzkiKes=";
+  };
+
+  dontUseCmakeConfigure = true;
+
+  build-system = [
+    setuptools
+    cmake
+    swig
+  ];
+
+  buildInputs =
+    [
+      cgal
+      gmp
+      mpfr
+      boost
+      zlib
+      tbb
+      eigen
+    ]
+    ++ lib.optionals withLAS [
+      LAStools
+    ];
+
+  dependencies = [
+    numpy
+  ];
+
+  pythonImportsCheck = [ "CGAL" ];
+
+  postFixup = lib.optionalString stdenv.hostPlatform.isElf ''
+    mv $out/${python.sitePackages}/{lib,CGAL/_lib}
+    for file in $out/${python.sitePackages}/CGAL/_*.so; do
+      patchelf "$file" --add-rpath $out/${python.sitePackages}/CGAL/_lib
+    done
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    (cd examples/python/
+      bash ./test.sh
+      cat error.txt
+      if grep -qi ' run error$' <error.txt; then
+        false
+      fi
+    )
+    runHook postCheck
+  '';
+
+  meta = {
+    description = "CGAL bindings using SWIG";
+    homepage = "https://github.com/CGAL/cgal-swig-bindings";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ pbsds ];
+    # error: no template named 'unary_function' in namespace 'boost::functional::detail'
+    broken = stdenv.hostPlatform.isDarwin;
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index a6db98bd998e..f3cc6f90e0ca 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -2156,6 +2156,10 @@ self: super: with self; {
 
   cftime = callPackage ../development/python-modules/cftime { };
 
+  cgal = callPackage ../development/python-modules/cgal {
+    inherit (pkgs) cgal;
+  };
+
   cgen = callPackage ../development/python-modules/cgen { };
 
   cgroup-utils = callPackage ../development/python-modules/cgroup-utils { };