From 585e0d8f9808993ab37472825d94ab1aa0e2484b Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:53:41 +0200
Subject: [PATCH 1/3] enpass-mac: init at 6.11.8.1861

---
 pkgs/by-name/en/enpass-mac/package.nix | 57 ++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pkgs/by-name/en/enpass-mac/package.nix

diff --git a/pkgs/by-name/en/enpass-mac/package.nix b/pkgs/by-name/en/enpass-mac/package.nix
new file mode 100644
index 000000000000..f06f8e790670
--- /dev/null
+++ b/pkgs/by-name/en/enpass-mac/package.nix
@@ -0,0 +1,57 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  gzip,
+  xar,
+  cpio,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "enpass-mac";
+  version = "6.11.8.1861";
+
+  src = fetchurl {
+    url = "https://dl.enpass.io/stable/mac/package/${finalAttrs.version}/Enpass.pkg";
+    hash = "sha256-n0ClsyGTS52ms161CJihIzBI5GjiMIF6HEJ59+jciq8=";
+  };
+
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  dontFixup = true;
+
+  nativeBuildInputs = [
+    gzip
+    xar
+    cpio
+  ];
+
+  unpackPhase = ''
+    runHook preUnpack
+
+    xar -xf $src
+    gunzip -dc Enpass_temp.pkg/Payload | cpio -i
+
+    runHook postUnpack
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/Applications
+    mv Enpass.app $out/Applications
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Choose your own safest place to store passwords";
+    homepage = "https://www.enpass.io";
+    changelog = "https://www.enpass.io/release-notes/macos-website-ver/";
+    license = [ lib.licenses.unfree ];
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    maintainers = with lib.maintainers; [ DimitarNestorov ];
+    platforms = lib.platforms.darwin;
+  };
+})

From 7ab2818d8955ed5643e00846889305cd85ce996e Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:53:42 +0200
Subject: [PATCH 2/3] enpass-mac: add update script

---
 pkgs/by-name/en/enpass-mac/package.nix | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)

diff --git a/pkgs/by-name/en/enpass-mac/package.nix b/pkgs/by-name/en/enpass-mac/package.nix
index f06f8e790670..d09d086a97c9 100644
--- a/pkgs/by-name/en/enpass-mac/package.nix
+++ b/pkgs/by-name/en/enpass-mac/package.nix
@@ -5,6 +5,11 @@
   gzip,
   xar,
   cpio,
+  writeShellApplication,
+  curl,
+  cacert,
+  gawk,
+  common-updater-scripts,
 }:
 
 stdenvNoCC.mkDerivation (finalAttrs: {
@@ -45,6 +50,21 @@ stdenvNoCC.mkDerivation (finalAttrs: {
     runHook postInstall
   '';
 
+  passthru.updateScript = lib.getExe (writeShellApplication {
+    name = "enpass-mac-update-script";
+    runtimeInputs = [
+      curl
+      cacert
+      gawk
+      common-updater-scripts
+    ];
+    text = ''
+      url="https://www.enpass.io/download/macos/website/stable"
+      version=$(curl -Ls -o /dev/null -w "%{url_effective}" "$url" | awk -F'/' '{print $7}')
+      update-source-version enpass-mac "$version"
+    '';
+  });
+
   meta = {
     description = "Choose your own safest place to store passwords";
     homepage = "https://www.enpass.io";

From e291aba410532c61fc07e973ec612f53c86a522c Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:53:42 +0200
Subject: [PATCH 3/3] enpass-mac: add version check

---
 pkgs/by-name/en/enpass-mac/package.nix | 14 ++++++++++++++
 1 file changed, 14 insertions(+)

diff --git a/pkgs/by-name/en/enpass-mac/package.nix b/pkgs/by-name/en/enpass-mac/package.nix
index d09d086a97c9..ecc81914c6a7 100644
--- a/pkgs/by-name/en/enpass-mac/package.nix
+++ b/pkgs/by-name/en/enpass-mac/package.nix
@@ -10,6 +10,10 @@
   cacert,
   gawk,
   common-updater-scripts,
+  versionCheckHook,
+  writeShellScript,
+  coreutils,
+  xcbuild,
 }:
 
 stdenvNoCC.mkDerivation (finalAttrs: {
@@ -65,6 +69,16 @@ stdenvNoCC.mkDerivation (finalAttrs: {
     '';
   });
 
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = writeShellScript "version-check" ''
+    marketing_version=$(${xcbuild}/bin/PlistBuddy -c "Print :CFBundleShortVersionString" "$1" | ${coreutils}/bin/tr -d '"')
+    build_version=$(${xcbuild}/bin/PlistBuddy -c "Print :CFBundleVersion" "$1")
+
+    echo $marketing_version.$build_version
+  '';
+  versionCheckProgramArg = [ "${placeholder "out"}/Applications/Enpass.app/Contents/Info.plist" ];
+  doInstallCheck = true;
+
   meta = {
     description = "Choose your own safest place to store passwords";
     homepage = "https://www.enpass.io";