diff --git a/pkgs/tools/text/sgrep/default.nix b/pkgs/tools/text/sgrep/default.nix
new file mode 100644
index 000000000000..f3d23d166696
--- /dev/null
+++ b/pkgs/tools/text/sgrep/default.nix
@@ -0,0 +1,39 @@
+{ stdenv, sgrep, fetchurl, runCommand, lib, m4, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "sgrep";
+  version = "1.94a";
+
+  src = fetchurl {
+    url = "https://www.cs.helsinki.fi/pub/Software/Local/Sgrep/sgrep-${version}.tar.gz";
+    sha256 = "sha256-1bFkeOOrRHNeJCg9LYldLJyAE5yVIo3zvbKsRGOV+vk=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  postInstall = ''
+    wrapProgram $out/bin/sgrep \
+      --prefix PATH : ${lib.makeBinPath [ m4 ]}
+  '';
+
+  passthru.tests.smokeTest = runCommand "test-sgrep" { } ''
+    expr='"<foo>" __ "</foo>"'
+    data="<foo>1</foo><bar>2</bar>"
+    ${sgrep}/bin/sgrep "$expr" <<<$data >$out
+    read result <$out
+    [[ $result = 1 ]]
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.cs.helsinki.fi/u/jjaakkol/sgrep.html";
+    description = "A grep for structured text formats such as XML";
+    longDescription = ''
+      sgrep (structured grep) is a tool for searching and indexing text,
+      SGML, XML and HTML files and filtering text streams using
+      structural criteria.
+    '';
+    platforms = platforms.unix;
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ eigengrau ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 022243a96f45..c69d97a72659 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1300,6 +1300,8 @@ with pkgs;
 
   sdlookup = callPackage ../tools/security/sdlookup { };
 
+  sgrep = callPackage ../tools/text/sgrep { };
+
   smbscan = callPackage ../tools/security/smbscan { };
 
   spectre-cli = callPackage ../tools/security/spectre-cli { };