From 8c3ca2627c6011130644bd83cfe940af95eb1ad8 Mon Sep 17 00:00:00 2001
From: amesgen <amesgen@amesgen.de>
Date: Wed, 25 Jan 2023 13:41:10 +0100
Subject: [PATCH] scriv: init at 1.2.0

---
 .../version-management/scriv/default.nix      | 57 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 59 insertions(+)
 create mode 100644 pkgs/applications/version-management/scriv/default.nix

diff --git a/pkgs/applications/version-management/scriv/default.nix b/pkgs/applications/version-management/scriv/default.nix
new file mode 100644
index 000000000000..b49969317ef3
--- /dev/null
+++ b/pkgs/applications/version-management/scriv/default.nix
@@ -0,0 +1,57 @@
+{ lib
+, python3
+, fetchPypi
+, pandoc
+, git
+, scriv
+, testers
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "scriv";
+  version = "1.2.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-u2HDD+pzFYpNGMKLu1eCHDCCRWg++w2Je9ReSnhWtHI=";
+  };
+
+  propagatedBuildInputs = with python3.pkgs; [
+    attrs
+    click
+    click-log
+    jinja2
+    requests
+  ] ++ lib.optionals (python3.pythonOlder "3.11") [
+    tomli
+  ];
+
+  nativeCheckInputs = with python3.pkgs; [
+    pytestCheckHook
+    coverage
+    freezegun
+    pudb
+    pytest-mock
+    responses
+    pyyaml
+
+    pandoc
+    git
+  ];
+  disabledTests = [
+    # assumes we have checked out the full repo (including remotes)
+    "test_real_get_github_repos"
+  ];
+
+  passthru.tests = {
+    version = testers.testVersion { package = scriv; };
+  };
+
+  meta = {
+    description = "Command-line tool for helping developers maintain useful changelogs.";
+    homepage = "https://github.com/nedbat/scriv";
+    changelog = "https://github.com/nedbat/scriv/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ amesgen ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index c46a2637ca32..f86a24f79bce 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2424,6 +2424,8 @@ with pkgs;
 
   sakura = callPackage ../applications/terminal-emulators/sakura { };
 
+  scriv = callPackage ../applications/version-management/scriv { };
+
   st = callPackage ../applications/terminal-emulators/st {
     conf = config.st.conf or null;
     patches = config.st.patches or [];