From fc34fc1c85a3807d384f0b7814637f65b7b2ffcb Mon Sep 17 00:00:00 2001
From: Anthony ROUSSEL <anthony@roussel.dev>
Date: Wed, 4 Sep 2024 22:09:16 +0200
Subject: [PATCH] python311Packages.python-magnumclient: init at 4.7.0

Add Magnum Client package, a client for the OpenStack Magnum container orchestration engine service.
---
 .../python-magnumclient/default.nix           | 97 +++++++++++++++++++
 .../python-openstackclient/default.nix        |  2 +
 pkgs/top-level/all-packages.nix               |  1 +
 pkgs/top-level/python-packages.nix            |  2 +
 4 files changed, 102 insertions(+)
 create mode 100644 pkgs/development/python-modules/python-magnumclient/default.nix

diff --git a/pkgs/development/python-modules/python-magnumclient/default.nix b/pkgs/development/python-modules/python-magnumclient/default.nix
new file mode 100644
index 000000000000..06866a59ce84
--- /dev/null
+++ b/pkgs/development/python-modules/python-magnumclient/default.nix
@@ -0,0 +1,97 @@
+{
+  lib,
+  buildPythonPackage,
+  cryptography,
+  decorator,
+  fetchFromGitHub,
+  fixtures,
+  keystoneauth1,
+  openstackdocstheme,
+  os-client-config,
+  osc-lib,
+  oslo-i18n,
+  oslo-log,
+  oslo-serialization,
+  oslo-utils,
+  oslotest,
+  osprofiler,
+  pbr,
+  prettytable,
+  python-openstackclient,
+  pythonOlder,
+  requests-mock,
+  requests,
+  setuptools,
+  sphinxHook,
+  stestr,
+  testtools,
+}:
+
+buildPythonPackage rec {
+  pname = "python-magnumclient";
+  version = "4.7.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchFromGitHub {
+    owner = "openstack";
+    repo = "python-magnumclient";
+    rev = "refs/tags/${version}";
+    hash = "sha256-2JHI3CB/DSZZ4LXzL3PCUSmubTciUXtZkc5jpeEc4kk=";
+  };
+
+  env.PBR_VERSION = version;
+
+  nativeBuildInputs = [
+    openstackdocstheme
+    sphinxHook
+  ];
+
+  sphinxBuilders = [ "man" ];
+
+  build-system = [
+    pbr
+    setuptools
+  ];
+
+  dependencies = [
+    cryptography
+    decorator
+    keystoneauth1
+    os-client-config
+    osc-lib
+    oslo-i18n
+    oslo-log
+    oslo-serialization
+    oslo-utils
+    prettytable
+    requests
+  ];
+
+  nativeCheckInputs = [
+    fixtures
+    python-openstackclient
+    osprofiler
+    oslotest
+    requests-mock
+    stestr
+    testtools
+  ];
+
+  checkPhase = ''
+    runHook preCheck
+    stestr run
+    runHook postCheck
+  '';
+
+  pythonImportsCheck = [ "magnumclient" ];
+
+  meta = {
+    homepage = "https://github.com/openstack/python-magnumclient";
+    description = "Client library for OpenStack Magnum API";
+    license = lib.licenses.asl20;
+    mainProgram = "magnum";
+    maintainers = lib.teams.openstack.members;
+  };
+}
diff --git a/pkgs/development/python-modules/python-openstackclient/default.nix b/pkgs/development/python-modules/python-openstackclient/default.nix
index 3f3989283f74..dcc7464297e8 100644
--- a/pkgs/development/python-modules/python-openstackclient/default.nix
+++ b/pkgs/development/python-modules/python-openstackclient/default.nix
@@ -12,6 +12,7 @@
   python-heatclient,
   python-ironicclient,
   python-keystoneclient,
+  python-magnumclient,
   python-manilaclient,
   python-mistralclient,
   python-neutronclient,
@@ -74,6 +75,7 @@ buildPythonPackage rec {
         python-designateclient
         python-heatclient
         python-ironicclient
+        python-magnumclient
         python-manilaclient
         python-mistralclient
         python-neutronclient
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 804ab2b4ac35..9ffa0ae9dc1c 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -22944,6 +22944,7 @@ with pkgs;
   glanceclient = with python311Packages; toPythonApplication python-glanceclient;
   heatclient = with python311Packages; toPythonApplication python-heatclient;
   ironicclient = with python311Packages; toPythonApplication python-ironicclient;
+  magnumclient = with python311Packages; toPythonApplication python-magnumclient;
   manilaclient = with python311Packages; toPythonApplication python-manilaclient;
   mistralclient = with python311Packages; toPythonApplication python-mistralclient;
   swiftclient = with python311Packages; toPythonApplication python-swiftclient;
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 2dad059a3965..a15c969a0fa2 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12641,6 +12641,8 @@ self: super: with self; {
 
   python-magic = callPackage ../development/python-modules/python-magic { };
 
+  python-magnumclient = callPackage ../development/python-modules/python-magnumclient { };
+
   python-manilaclient = callPackage ../development/python-modules/python-manilaclient { };
 
   python-mapnik = callPackage ../development/python-modules/python-mapnik rec {