From 438a62e1beaeda3d93a472278175b5fafec84641 Mon Sep 17 00:00:00 2001
From: LoC <loc@locrealloc.de>
Date: Sat, 26 Oct 2024 21:20:44 +0200
Subject: [PATCH] ytdl-sub: init at 2024.10.26

---
 pkgs/by-name/yt/ytdl-sub/package.nix | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 pkgs/by-name/yt/ytdl-sub/package.nix

diff --git a/pkgs/by-name/yt/ytdl-sub/package.nix b/pkgs/by-name/yt/ytdl-sub/package.nix
new file mode 100644
index 000000000000..71a0ee253521
--- /dev/null
+++ b/pkgs/by-name/yt/ytdl-sub/package.nix
@@ -0,0 +1,49 @@
+{
+  python3Packages,
+  fetchPypi,
+  ffmpeg,
+  lib,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "ytdl-sub";
+  version = "2024.10.26";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit version;
+    pname = "ytdl_sub";
+    hash = "sha256-qfEPHhCB/Avl+nUIk2+ZVseg8ATP/LQmLvX/H9rhp7M=";
+  };
+
+  build-system = with python3Packages; [
+    setuptools
+    wheel
+  ];
+
+  dependencies = with python3Packages; [
+    yt-dlp
+    colorama
+    mergedeep
+    mediafile
+    pyyaml
+  ];
+
+  makeWrapperArgs = [
+    "--set YTDL_SUB_FFMPEG_PATH ${lib.getExe' ffmpeg "ffmpeg"}"
+    "--set YTDL_SUB_FFPROBE_PATH ${lib.getExe' ffmpeg "ffprobe"}"
+  ];
+
+  meta = {
+    homepage = "https://github.com/jmbannon/ytdl-sub";
+    description = "Lightweight tool to automate downloading and metadata generation with yt-dlp";
+    longDescription = ''
+      ytdl-sub is a command-line tool that downloads media via yt-dlp and prepares it for your favorite media player, including Kodi, Jellyfin, Plex, Emby, and modern music players. No additional plugins or external scrapers are needed.
+    '';
+    changelog = "https://github.com/jmbannon/ytdl-sub/releases/tag/${version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [
+      loc
+    ];
+    mainProgram = "ytdl-sub";
+  };
+}