From 401adf55dfc9ce41ad8366b93f348d1690f71e7f Mon Sep 17 00:00:00 2001
From: Defelo <mail@defelo.de>
Date: Tue, 21 Oct 2025 20:04:55 +0200
Subject: [PATCH] sigsum: init at 0.11.2

---
 pkgs/by-name/si/sigsum/package.nix | 51 ++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/si/sigsum/package.nix

diff --git a/pkgs/by-name/si/sigsum/package.nix b/pkgs/by-name/si/sigsum/package.nix
new file mode 100644
index 000000000000..03bf0d55345b
--- /dev/null
+++ b/pkgs/by-name/si/sigsum/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitLab,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "sigsum";
+  version = "0.11.2";
+
+  src = fetchFromGitLab {
+    domain = "git.glasklar.is";
+    group = "sigsum";
+    owner = "core";
+    repo = "sigsum-go";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-oaYquy0N8yHfKLoNEv8Vte3dpp/UQFZ74mZHin8dDzw=";
+  };
+
+  postPatch = ''
+    substituteInPlace internal/version/version.go \
+      --replace-fail "info.Main.Version" '"${finalAttrs.version}"'
+  '';
+
+  vendorHash = "sha256-8Tyhd13PRTO2dGOdhkgYmwsVzWfqwOpZ9XSsAtiCcyM=";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  excludedPackages = [ "./test" ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = "${placeholder "out"}/bin/sigsum-key";
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "System for public and transparent logging of signed checksums";
+    homepage = "https://www.sigsum.org/";
+    downloadPage = "https://git.glasklar.is/sigsum/core/sigsum-go";
+    changelog = "https://git.glasklar.is/sigsum/core/sigsum-go/-/blob/v${finalAttrs.version}/NEWS";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ defelo ];
+  };
+})