From a6cf69f4c4346a15e7b247568b8a0772a06429a2 Mon Sep 17 00:00:00 2001
From: Azat Bahawi <azat@bahawi.net>
Date: Thu, 14 Jul 2022 02:39:54 +0300
Subject: [PATCH] iaito: init at 5.7.0

---
 pkgs/tools/security/iaito/default.nix | 61 +++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix       |  2 +
 2 files changed, 63 insertions(+)
 create mode 100644 pkgs/tools/security/iaito/default.nix

diff --git a/pkgs/tools/security/iaito/default.nix b/pkgs/tools/security/iaito/default.nix
new file mode 100644
index 000000000000..e2a4d37a9779
--- /dev/null
+++ b/pkgs/tools/security/iaito/default.nix
@@ -0,0 +1,61 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, pkg-config
+, qtbase
+, qttools
+, radare2
+, wrapQtAppsHook
+, zip
+, nix-update-script
+}:
+
+stdenv.mkDerivation rec {
+  pname = "iaito";
+  version = "5.7.0";
+
+  src = fetchFromGitHub {
+    owner = "radareorg";
+    repo = pname;
+    rev = version;
+    fetchSubmodules = true;
+    sha256 = "sha256-qEJTsS669eEwo2iiuybN72O5oopCaGEkju8+ekjw2zk=";
+  };
+
+  nativeBuildInputs = [ pkg-config qttools wrapQtAppsHook zip ];
+  buildInputs = [ radare2 qtbase ];
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace "git submodule update --init" ""
+  '';
+
+  NIX_CFLAGS_COMPILE = [ "-I${radare2}/include/libr" "-I${radare2}/include/libr/sdb" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 build/iaito $out/bin/iaito
+    install -Dm644 $src/src/org.radare.iaito.appdata.xml $out/share/metainfo/org.radare.iaito.appdata.xml
+    install -Dm644 $src/src/org.radare.iaito.desktop $out/share/applications/org.radare.iaito.desktop
+    install -Dm644 $src/src/img/iaito-o.svg $out/share/pixmaps/iaito-o.svg
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script {
+    attrPath = pname;
+  };
+
+  meta = with lib; {
+    description = "Official frontend of radare2";
+    longDescription = ''
+      The official graphical interface for radare2, a libre reverse engineering
+      framework.
+    '';
+    homepage = "https://github.com/radareorg/iaito";
+    changelog = "https://github.com/radareorg/iaito/releases/tag/${src.rev}";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ azahi ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index fa162d3d0eeb..a377e106d3f2 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -7299,6 +7299,8 @@ with pkgs;
 
   iannix = libsForQt5.callPackage ../applications/audio/iannix { };
 
+  iaito = libsForQt5.callPackage ../tools/security/iaito { };
+
   jamulus = libsForQt5.callPackage ../applications/audio/jamulus { };
 
   ibm-sw-tpm2 = callPackage ../tools/security/ibm-sw-tpm2 { };