diff --git a/pkgs/by-name/ke/keymap-drawer/package.nix b/pkgs/by-name/ke/keymap-drawer/package.nix
new file mode 100644
index 000000000000..201141b2f7c4
--- /dev/null
+++ b/pkgs/by-name/ke/keymap-drawer/package.nix
@@ -0,0 +1,4 @@
+{
+  python3Packages,
+}:
+python3Packages.toPythonApplication python3Packages.keymap-drawer
diff --git a/pkgs/development/python-modules/keymap-drawer/default.nix b/pkgs/development/python-modules/keymap-drawer/default.nix
new file mode 100644
index 000000000000..0fe1961748d7
--- /dev/null
+++ b/pkgs/development/python-modules/keymap-drawer/default.nix
@@ -0,0 +1,69 @@
+{
+  lib,
+
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+
+  nix-update-script,
+  pcpp,
+  platformdirs,
+  poetry-core,
+  pydantic,
+  pydantic-settings,
+  pyparsing,
+  pyyaml,
+  tree-sitter,
+  tree-sitter-grammars,
+  versionCheckHook,
+}:
+let
+  version = "0.22.0";
+in
+buildPythonPackage {
+  inherit version;
+  pname = "keymap-drawer";
+  pyproject = true;
+  disabled = pythonOlder "3.12";
+
+  src = fetchFromGitHub {
+    owner = "caksoylar";
+    repo = "keymap-drawer";
+    tag = "v${version}";
+    hash = "sha256-SPnIfrUA0M9xznjEe60T+0VHh9lCmY4cni9hyqFlZqM=";
+  };
+
+  build-system = [ poetry-core ];
+
+  dependencies = [
+    pcpp
+    platformdirs
+    pydantic
+    pydantic-settings
+    pyparsing
+    pyyaml
+    tree-sitter
+    tree-sitter-grammars.tree-sitter-devicetree
+  ];
+
+  nativeCheckInputs = [
+    versionCheckHook
+  ];
+
+  pythonImportsCheck = [ "keymap_drawer" ];
+
+  versionCheckProgram = "${placeholder "out"}/bin/keymap";
+  versionCheckProgramArg = "--version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Module and CLI tool to help parse and draw keyboard layouts";
+    homepage = "https://github.com/caksoylar/keymap-drawer";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      MattSturgeon
+    ];
+    mainProgram = "keymap";
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 68a80e0a1055..8ca4353f3c65 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7584,6 +7584,8 @@ self: super: with self; {
 
   keyboard = callPackage ../development/python-modules/keyboard { };
 
+  keymap-drawer = callPackage ../development/python-modules/keymap-drawer { };
+
   keyring = callPackage ../development/python-modules/keyring { };
 
   keyring-pass = callPackage ../development/python-modules/keyring-pass { };