From 3a51643c664b45ba4161305fbc1fa04007dc102c Mon Sep 17 00:00:00 2001
From: Mirza Arnaut <mirza.arnaut45@gmail.com>
Date: Sat, 25 Apr 2026 21:44:22 +0200
Subject: [PATCH] onedpl: init at 2022.11.1

Intel's onedpl library packaged using the `intel-llvm.stdenv`.
---
 pkgs/by-name/on/onedpl/package.nix | 54 ++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 pkgs/by-name/on/onedpl/package.nix

diff --git a/pkgs/by-name/on/onedpl/package.nix b/pkgs/by-name/on/onedpl/package.nix
new file mode 100644
index 000000000000..fb0e606ab890
--- /dev/null
+++ b/pkgs/by-name/on/onedpl/package.nix
@@ -0,0 +1,54 @@
+{
+  lib,
+  intelLlvmStdenv,
+  fetchFromGitHub,
+  cmake,
+  onetbb,
+  nix-update-script,
+}:
+intelLlvmStdenv.mkDerivation (finalAttrs: {
+  pname = "onedpl";
+  version = "2022.11.1";
+
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  src = fetchFromGitHub {
+    owner = "uxlfoundation";
+    repo = "oneDPL";
+    tag = "oneDPL-${finalAttrs.version}-release";
+    hash = "sha256-NfyV34mdKfCxlU+l6ETKWcC9MwvVEgwcBedtLe6WCV4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    onetbb
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeFeature "ONEDPL_BACKEND" "dpcpp")
+  ];
+
+  # Build times for the tests are excessive
+  # and to be truly meaningful, they'd require a GPU
+  doCheck = false;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "'oneDPL-(.*)-release'"
+    ];
+  };
+
+  meta = {
+    description = "oneAPI DPC++ Library (oneDPL)";
+    homepage = "http://uxlfoundation.github.io/oneDPL";
+    changelog = "https://github.com/uxlfoundation/oneDPL/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ arunoruto ];
+    platforms = lib.platforms.all;
+  };
+})