From 396d1f10e642cafbdff950321dcb0b817a71b873 Mon Sep 17 00:00:00 2001
From: Guilhem Saurel <guilhem.saurel@laas.fr>
Date: Tue, 27 Aug 2024 01:11:10 +0200
Subject: [PATCH] tsid: init at 1.7.1

---
 pkgs/by-name/ts/tsid/package.nix   | 66 ++++++++++++++++++++++++++++++
 pkgs/top-level/python-packages.nix |  5 +++
 2 files changed, 71 insertions(+)
 create mode 100644 pkgs/by-name/ts/tsid/package.nix

diff --git a/pkgs/by-name/ts/tsid/package.nix b/pkgs/by-name/ts/tsid/package.nix
new file mode 100644
index 000000000000..054857f8b222
--- /dev/null
+++ b/pkgs/by-name/ts/tsid/package.nix
@@ -0,0 +1,66 @@
+{
+  cmake,
+  doxygen,
+  eiquadprog,
+  fetchFromGitHub,
+  lib,
+  osqp-eigen,
+  pkg-config,
+  pinocchio,
+  proxsuite,
+  stdenv,
+  pythonSupport ? false,
+  python3Packages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "tsid";
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "stack-of-tasks";
+    repo = "tsid";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-id6OCOX01o41Z5kqzwvjYa5uoQZtzhRaFBuOBhbLcTA=";
+  };
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
+    (lib.cmakeBool "BUILD_WITH_OSQP" true)
+    (lib.cmakeBool "BUILD_WITH_PROXQP" true)
+    (lib.cmakeBool "INSTALL_DOCUMENTATION" true)
+  ];
+
+  outputs = [
+    "doc"
+    "out"
+  ];
+
+  nativeBuildInputs = [
+    doxygen
+    cmake
+    pkg-config
+  ] ++ lib.optional pythonSupport python3Packages.python;
+
+  propagatedBuildInputs =
+    [
+      eiquadprog
+      osqp-eigen
+      proxsuite
+    ]
+    ++ lib.optional (!pythonSupport) pinocchio ++ lib.optional pythonSupport python3Packages.pinocchio;
+
+  doCheck = true;
+  # pythonImportsCheck, but in stdenv.mkDerivation
+  postInstall = lib.optionalString pythonSupport ''
+    PYTHONPATH=$out/${python3Packages.python.sitePackages}:$PYTHONPATH
+    python -c "import tsid"
+  '';
+
+  meta = {
+    description = "Efficient Task Space Inverse Dynamics (TSID) based on Pinocchio";
+    homepage = "https://github.com/stack-of-tasks/tsid";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ nim65s ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index f717a160919e..ad6482df0a21 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -16030,6 +16030,11 @@ self: super: with self; {
 
   tsfresh = callPackage ../development/python-modules/tsfresh { };
 
+  tsid = toPythonModule (pkgs.tsid.override {
+    pythonSupport = true;
+    python3Packages = self;
+  });
+
   tskit = callPackage ../development/python-modules/tskit { };
 
   ttach = callPackage ../development/python-modules/ttach { };