diff --git a/pkgs/by-name/co/colcon/package.nix b/pkgs/by-name/co/colcon/package.nix
new file mode 100644
index 000000000000..c88b051d468a
--- /dev/null
+++ b/pkgs/by-name/co/colcon/package.nix
@@ -0,0 +1 @@
+{ python3Packages }: with python3Packages; toPythonApplication colcon
diff --git a/pkgs/development/python-modules/colcon/default.nix b/pkgs/development/python-modules/colcon/default.nix
new file mode 100644
index 000000000000..1c6c0cc37be0
--- /dev/null
+++ b/pkgs/development/python-modules/colcon/default.nix
@@ -0,0 +1,68 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  # build-system
+  setuptools,
+  # dependencies
+  distlib,
+  empy,
+  packaging,
+  python-dateutil,
+  pyyaml,
+  # tests
+  pytestCheckHook,
+  pytest-cov-stub,
+  pytest-repeat,
+  pytest-rerunfailures,
+}:
+buildPythonPackage rec {
+  pname = "colcon-core";
+  version = "0.19.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "colcon";
+    repo = "colcon-core";
+    tag = version;
+    hash = "sha256-R/TVHPT305PwaVSisP0TtbgjCFBwCZkXOAgkYhCKpyY=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    empy
+    distlib
+    packaging
+    python-dateutil
+    pyyaml
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-cov-stub
+    pytest-repeat
+    pytest-rerunfailures
+  ];
+
+  disabledTestPaths = [
+    # Skip the linter and spell check tests that require additional dependencies
+    "test/test_flake8.py"
+    "test/test_spell_check.py"
+  ];
+
+  pythonImportsCheck = [ "colcon_core" ];
+
+  pythonRemoveDeps = [
+    # We use pytest-cov-stub instead (and it is not a runtime dependency anyways)
+    "pytest-cov"
+  ];
+
+  meta = {
+    description = "Command line tool to build sets of software packages";
+    homepage = "https://github.com/colcon/colcon-core";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ guelakais ];
+    mainProgram = "colcon";
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 442976c40a3b..7f725c55c9c1 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -2649,6 +2649,8 @@ self: super: with self; {
 
   colbert-ai = callPackage ../development/python-modules/colbert-ai { };
 
+  colcon = callPackage ../development/python-modules/colcon { };
+
   collections-extended = callPackage ../development/python-modules/collections-extended { };
 
   collidoscope = callPackage ../development/python-modules/collidoscope { };