From 383adab9e0e6c4563e8585b65271abcfa4cd2cb2 Mon Sep 17 00:00:00 2001
From: Francesco Gazzetta <fgaz@fgaz.me>
Date: Fri, 17 May 2024 15:31:15 +0200
Subject: [PATCH] domino-chain: init at 1.1

---
 .../do/domino-chain/algorithm-header.patch    | 13 +++
 pkgs/by-name/do/domino-chain/package.nix      | 84 +++++++++++++++++++
 2 files changed, 97 insertions(+)
 create mode 100644 pkgs/by-name/do/domino-chain/algorithm-header.patch
 create mode 100644 pkgs/by-name/do/domino-chain/package.nix

diff --git a/pkgs/by-name/do/domino-chain/algorithm-header.patch b/pkgs/by-name/do/domino-chain/algorithm-header.patch
new file mode 100644
index 000000000000..f356554cf8b1
--- /dev/null
+++ b/pkgs/by-name/do/domino-chain/algorithm-header.patch
@@ -0,0 +1,13 @@
+diff --git a/src/domino-chain/tools.cpp b/src/domino-chain/tools.cpp
+index 0eaa592..e91c760 100644
+--- a/src/domino-chain/tools.cpp
++++ b/src/domino-chain/tools.cpp
+@@ -48,6 +48,8 @@
+ 
+ #include <boost/filesystem.hpp>
+ 
++#include <algorithm>
++
+ uint64_t getTime(void)
+ {
+ #if defined(WIN32) || defined(_WIN32)
diff --git a/pkgs/by-name/do/domino-chain/package.nix b/pkgs/by-name/do/domino-chain/package.nix
new file mode 100644
index 000000000000..4d0ced53f0f1
--- /dev/null
+++ b/pkgs/by-name/do/domino-chain/package.nix
@@ -0,0 +1,84 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  boost,
+  freefont_ttf,
+  fribidi,
+  gettext,
+  imagemagick,
+  libpng,
+  lua,
+  pkg-config,
+  povray,
+  SDL2,
+  SDL2_image,
+  SDL2_mixer,
+  SDL2_ttf,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "domino-chain";
+  version = "1.1";
+
+  src = fetchFromGitLab {
+    owner = "domino-chain";
+    repo = "domino-chain.gitlab.io";
+    tag = finalAttrs.version;
+    hash = "sha256-ERR5QwQpTFLeAijlGtGU0Lpd40II/L5i3muYDN2EfX4=";
+  };
+
+  patches = [
+    ./algorithm-header.patch
+  ];
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-warn /usr/share/fonts/truetype/freefont/ ${freefont_ttf}/share/fonts/truetype/
+    substituteInPlace src/domino-chain/screen.cpp \
+      --replace-fail /usr/share/fonts/truetype/freefont/ ${freefont_ttf}/share/fonts/truetype/
+  '';
+
+  nativeBuildInputs = [
+    gettext
+    imagemagick
+    pkg-config
+    povray
+  ];
+
+  buildInputs = [
+    boost
+    freefont_ttf
+    fribidi
+    libpng
+    lua
+    SDL2
+    SDL2_image
+    SDL2_mixer
+    SDL2_ttf
+    zlib
+  ];
+
+  enableParallelBuilding = true;
+
+  __structuredAttrs = true;
+  makeFlags = [
+    "PREFIX=$(out)"
+    "POVRAY=povray Work_Threads=$(NIX_BUILD_CORES)"
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString [
+    "-I${lib.getDev SDL2}/include/SDL2"
+    "-I${lib.getDev SDL2_mixer}/include/SDL2"
+  ];
+
+  meta = {
+    description = "Rearrange dominoes on different platforms to start a chain reaction";
+    homepage = "https://domino-chain.gitlab.io/";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ fgaz ];
+    mainProgram = "domino-chain";
+    platforms = lib.platforms.all;
+  };
+})