From 3f3d97297f8639a6a1f4f8ed7a72c2792298edd1 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Alja=C5=BE=20Mur=20Er=C5=BEen?= <aljaz@erzen.si>
Date: Mon, 1 Sep 2025 14:18:11 +0200
Subject: [PATCH 1/2] maintainers: add aljazerzen

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index abd81d745a8b..8c5e8fc78840 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -1342,6 +1342,12 @@
     githubId = 8614547;
     name = "Ali Caglayan";
   };
+  aljazerzen = {
+    email = "aljaz@erzen.si";
+    github = "aljazerzen";
+    githubId = 11072061;
+    name = "Aljaž Mur Eržen";
+  };
   alkasm = {
     email = "alexreynolds00@gmail.com";
     github = "alkasm";

From c254e73904c090bf54d5c642e8ad15fdd88b5e55 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Alja=C5=BE=20Mur=20Er=C5=BEen?= <aljaz@erzen.si>
Date: Sun, 9 Nov 2025 14:23:21 +0100
Subject: [PATCH 2/2] zensical: init at 0.0.15

[Zensical][1] is a static site generator for documentation, replacing
Material for MkDocs.
This PR adds a package for its CLI, written in Rust and Python.

[1]: https://github.com/zensical/zensical

Co-authored-by: Acid Bong <acidbong@tilde.club>
Co-authored-by: Yiyu Zhou <yiyuzhou19@gmail.com>
---
 pkgs/by-name/ze/zensical/package.nix | 59 ++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 pkgs/by-name/ze/zensical/package.nix

diff --git a/pkgs/by-name/ze/zensical/package.nix b/pkgs/by-name/ze/zensical/package.nix
new file mode 100644
index 000000000000..b8e890f3115b
--- /dev/null
+++ b/pkgs/by-name/ze/zensical/package.nix
@@ -0,0 +1,59 @@
+{
+  lib,
+  fetchPypi,
+  rustPlatform,
+  python3Packages,
+  versionCheckHook,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "zensical";
+  version = "0.0.15";
+  pyproject = true;
+
+  # We fetch from PyPi, because GitHub repo does not contain all sources.
+  # The publish process also copies in assets from zensical/ui.
+  # We could combine sources, but then nix-update won't work.
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-syAMkbMDcGccULi0qkHCDlX/KBS5AD7iPJtvkjoMGb4=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit pname version src;
+    hash = "sha256-Sg4gl23aK6yPZ3Hdi+IzTGnx8wEAkSL0SrKGVdMRJ2s=";
+  };
+
+  nativeBuildInputs = with rustPlatform; [
+    maturinBuildHook
+    cargoSetupHook
+  ];
+
+  dependencies = with python3Packages; [
+    click
+    deepmerge
+    markdown
+    pygments
+    pymdown-extensions
+    pyyaml
+  ];
+
+  nativeCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+
+  meta = {
+    description = "Static site generator for documentation";
+    longDescription = ''
+      Zensical is a modern static site generator designed to simplify
+      building and maintaining project documentation.  It's built by
+      the creators of Material for MkDocs and shares the same core
+      design principles and philosophy – batteries included, easy to
+      use, with powerful customization options.
+    '';
+    homepage = "https://zensical.org";
+    changelog = "https://github.com/zensical/zensical/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ aljazerzen ];
+    mainProgram = "zensical";
+  };
+}