From 3754b246c8f75f722b69b74da3e1237444ba6093 Mon Sep 17 00:00:00 2001
From: Elliot Cameron <nixpkgs-commits@deshaw.com>
Date: Mon, 17 Apr 2023 16:54:26 -0400
Subject: [PATCH] python3Packages.opentelemetry-sdk: init at 1.18.0

---
 .../opentelemetry-sdk/default.nix             | 66 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 68 insertions(+)
 create mode 100644 pkgs/development/python-modules/opentelemetry-sdk/default.nix

diff --git a/pkgs/development/python-modules/opentelemetry-sdk/default.nix b/pkgs/development/python-modules/opentelemetry-sdk/default.nix
new file mode 100644
index 000000000000..6ac7b8037fb7
--- /dev/null
+++ b/pkgs/development/python-modules/opentelemetry-sdk/default.nix
@@ -0,0 +1,66 @@
+{ lib
+, buildPythonPackage
+, pythonOlder
+, fetchFromGitHub
+, flaky
+, hatchling
+, opentelemetry-api
+, opentelemetry-semantic-conventions
+, opentelemetry-test-utils
+, setuptools
+, typing-extensions
+, pytestCheckHook
+}:
+
+let
+  self = buildPythonPackage {
+    pname = "opentelemetry-sdk";
+    version = "1.18.0";
+    disabled = pythonOlder "3.7";
+
+    src = fetchFromGitHub {
+      owner = "open-telemetry";
+      repo = "opentelemetry-python";
+      rev = "refs/tags/v${self.version}";
+      hash = "sha256-YMFSmzuvm/VA9Fpe7pbF9mnGQHOQpobWMb1iGRt+d3w=";
+      sparseCheckout = [ "/${self.pname}" ];
+    } + "/${self.pname}";
+
+    format = "pyproject";
+
+    nativeBuildInputs = [
+      hatchling
+    ];
+
+    propagatedBuildInputs = [
+      opentelemetry-api
+      opentelemetry-semantic-conventions
+      setuptools
+      typing-extensions
+    ];
+
+    nativeCheckInputs = [
+      flaky
+      opentelemetry-test-utils
+      pytestCheckHook
+    ];
+
+    disabledTestPaths = [
+      "tests/performance/benchmarks/"
+    ];
+
+    pythonImportsCheck = [ "opentelemetry.sdk" ];
+
+    doCheck = false;
+
+    # Enable tests via passthru to avoid cyclic dependency with opentelemetry-test-utils.
+    passthru.tests.${self.pname} = self.overridePythonAttrs { doCheck = true; };
+
+    meta = with lib; {
+      homepage = "https://opentelemetry.io";
+      description = "OpenTelemetry Python API and SDK";
+      license = licenses.asl20;
+      maintainers = teams.deshaw.members;
+    };
+  };
+in self
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 788b8e34c9c5..d55d0c8d3f60 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7100,6 +7100,8 @@ self: super: with self; {
 
   opentelemetry-semantic-conventions = callPackage ../development/python-modules/opentelemetry-semantic-conventions { };
 
+  opentelemetry-sdk = callPackage ../development/python-modules/opentelemetry-sdk { };
+
   openturns = toPythonModule (pkgs.openturns.override {
     python3Packages = self;
     enablePython = true;