From 36f91fc73f755a55d8aa045b00e791de49dc4475 Mon Sep 17 00:00:00 2001
From: Sefa Eyeoglu <contact@scrumplex.net>
Date: Fri, 30 Aug 2024 09:54:06 +0200
Subject: [PATCH] winbox4: init at 4.0beta9

Signed-off-by: Sefa Eyeoglu <contact@scrumplex.net>
---
 pkgs/by-name/wi/winbox4/package.nix | 78 +++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix     |  3 +-
 2 files changed, 80 insertions(+), 1 deletion(-)
 create mode 100644 pkgs/by-name/wi/winbox4/package.nix

diff --git a/pkgs/by-name/wi/winbox4/package.nix b/pkgs/by-name/wi/winbox4/package.nix
new file mode 100644
index 000000000000..ed5975f3d5e8
--- /dev/null
+++ b/pkgs/by-name/wi/winbox4/package.nix
@@ -0,0 +1,78 @@
+{
+  autoPatchelfHook,
+  copyDesktopItems,
+  fetchurl,
+  fontconfig,
+  freetype,
+  lib,
+  libGL,
+  libxkbcommon,
+  makeDesktopItem,
+  stdenvNoCC,
+  unzip,
+  xorg,
+  zlib,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "winbox";
+  version = "4.0beta9";
+
+  src = fetchurl {
+    name = "WinBox_Linux-${finalAttrs.version}.zip";
+    url = "https://download.mikrotik.com/routeros/winbox/${finalAttrs.version}/WinBox_Linux.zip";
+    hash = "sha256-129ejj3WxYx5kQTy6EOLtBolhx076yMVb5ymkAoXrwc=";
+  };
+
+  sourceRoot = ".";
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    copyDesktopItems
+    unzip
+  ];
+
+  buildInputs = [
+    fontconfig
+    freetype
+    libGL
+    libxkbcommon
+    xorg.libxcb
+    xorg.xcbutilimage
+    xorg.xcbutilkeysyms
+    xorg.xcbutilrenderutil
+    xorg.xcbutilwm
+    zlib
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm644 "assets/img/winbox.png" "$out/share/pixmaps/winbox.png"
+    install -Dm755 "WinBox" $out/bin/WinBox
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "winbox";
+      desktopName = "Winbox";
+      comment = "GUI administration for Mikrotik RouterOS";
+      exec = "WinBox";
+      icon = "winbox";
+      categories = [ "Utility" ];
+    })
+  ];
+
+  meta = {
+    description = "Graphical configuration utility for RouterOS-based devices";
+    homepage = "https://mikrotik.com";
+    downloadPage = "https://mikrotik.com/download";
+    changelog = "https://download.mikrotik.com/routeros/winbox/${finalAttrs.version}/CHANGELOG";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.unfree;
+    mainProgram = "WinBox";
+    maintainers = with lib.maintainers; [ Scrumplex yrd ];
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 207b82ffe11f..68c282b1caa8 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2025,7 +2025,8 @@ with pkgs;
 
   vrrtest = callPackage ../tools/video/vrrtest { };
 
-  winbox = callPackage ../tools/admin/winbox {
+  winbox = winbox3;
+  winbox3 = callPackage ../tools/admin/winbox {
     wine = wineWowPackages.stable;
   };