From 5c5876f84e0cb85438489405ba9bdc247c6ad43f Mon Sep 17 00:00:00 2001
From: Julia Brunenberg <julia@jjim.de>
Date: Mon, 1 Dec 2025 11:51:48 +0100
Subject: [PATCH] mvoice: init at 0-unstable-2025-09-19

---
 pkgs/by-name/mv/mvoice/package.nix | 82 ++++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 pkgs/by-name/mv/mvoice/package.nix

diff --git a/pkgs/by-name/mv/mvoice/package.nix b/pkgs/by-name/mv/mvoice/package.nix
new file mode 100644
index 000000000000..d5d9b1edb92f
--- /dev/null
+++ b/pkgs/by-name/mv/mvoice/package.nix
@@ -0,0 +1,82 @@
+{
+  lib,
+  stdenv,
+  gettext,
+  fltk-minimal,
+  alsa-lib,
+  opendht,
+  msgpack-cxx,
+  fmt,
+  gnutls,
+  nlohmann_json,
+  curl,
+  copyDesktopItems,
+  makeDesktopItem,
+  fetchFromGitHub,
+}:
+stdenv.mkDerivation {
+  pname = "mvoice";
+  version = "0-unstable-2025-09-19";
+
+  src = fetchFromGitHub {
+    owner = "n7tae";
+    repo = "mvoice";
+    rev = "aef3662ee6ef86ecb10a71dd686ca41a067162c0";
+    hash = "sha256-FosfD1949shlPXq594gdqodlXM3cGKpFi68tc+/YQ4g=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    fltk-minimal
+    gettext
+  ];
+
+  buildInputs = [
+    alsa-lib
+    curl
+    fltk-minimal
+    fmt
+    gnutls
+    msgpack-cxx
+    nlohmann_json
+    opendht
+  ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "mvoice";
+      desktopName = "MVoice";
+      comment = "MVoice by N7TAE - M17 figital voice gateway";
+      exec = "mvoice";
+      categories = [
+        "Network"
+        "X-Ham Radio"
+      ];
+    })
+  ];
+
+  postPatch = ''
+    # fix hardcoded paths in Makefile
+    substituteInPlace Makefile \
+      --replace-fail "g++" "\$(CXX)" \
+      --replace-fail "/bin/cp" "cp"
+  '';
+
+  makeFlags = [
+    "BASEDIR=$(out)"
+    "CFGDIR=.config/mvoice"
+    "DEBUG=false"
+    "USE44100=false"
+    "USE_DHT=true"
+  ];
+
+  meta = {
+    description = "M17 digital voice gateway and module for voice and data modes";
+    homepage = "https://github.com/n7tae/mvoice";
+    license = lib.licenses.gpl2Only;
+    platforms = lib.platforms.linux;
+    maintainers = [ lib.maintainers.juliabru ];
+  };
+}