From 330d2496449f47b8f6a1df5e93e18e0d2d39a77d Mon Sep 17 00:00:00 2001
From: Kenichi Kamiya <kachick1@gmail.com>
Date: Tue, 17 Mar 2026 02:52:10 +0900
Subject: [PATCH] betterleaks: init at 1.1.1

---
 pkgs/by-name/be/betterleaks/package.nix | 65 +++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/by-name/be/betterleaks/package.nix

diff --git a/pkgs/by-name/be/betterleaks/package.nix b/pkgs/by-name/be/betterleaks/package.nix
new file mode 100644
index 000000000000..0c4d6b2358d0
--- /dev/null
+++ b/pkgs/by-name/be/betterleaks/package.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  nix-update-script,
+  versionCheckHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "betterleaks";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "betterleaks";
+    repo = "betterleaks";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-PJGFvm+QoExUMliL6rvBAKKjt8Ce5VZfQxCYbpXUXfU=";
+  };
+
+  vendorHash = "sha256-lIblIctRnq//ic+most3g9Ff92XhfqbFfHrLdI0beQQ=";
+
+  ldflags = [
+    "-s"
+    "-X=github.com/betterleaks/betterleaks/version.Version=${finalAttrs.version}"
+  ];
+
+  subPackages = [
+    "."
+  ];
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  env.CGO_ENABLED = 0;
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd betterleaks \
+      --bash <($out/bin/betterleaks completion bash) \
+      --fish <($out/bin/betterleaks completion fish) \
+      --zsh <($out/bin/betterleaks completion zsh)
+  '';
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  doInstallCheck = true;
+  versionCheckProgram = "${placeholder "out"}/bin/betterleaks";
+  versionCheckProgramArg = "version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Scan code for secrets";
+    homepage = "https://github.com/betterleaks/betterleaks";
+    changelog = "https://github.com/betterleaks/betterleaks/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      kachick
+    ];
+    mainProgram = "betterleaks";
+  };
+})