From 31450c1f0a69b01e3c2bfde2fd126fe180c79d38 Mon Sep 17 00:00:00 2001
From: Lyn <me@fugi.dev>
Date: Fri, 17 Apr 2026 14:55:07 +0200
Subject: [PATCH] sable-unwrapped: init at 1.19.4

---
 pkgs/by-name/ci/cinny/package.nix           |  5 +-
 pkgs/by-name/sa/sable-unwrapped/package.nix | 80 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  5 ++
 3 files changed, 88 insertions(+), 2 deletions(-)
 create mode 100644 pkgs/by-name/sa/sable-unwrapped/package.nix

diff --git a/pkgs/by-name/ci/cinny/package.nix b/pkgs/by-name/ci/cinny/package.nix
index df494780e81d..02bfc4fca9cf 100644
--- a/pkgs/by-name/ci/cinny/package.nix
+++ b/pkgs/by-name/ci/cinny/package.nix
@@ -4,15 +4,16 @@
   stdenvNoCC,
   writeText,
   conf ? { },
+  pname ? "cinny",
 }:
 let
-  configOverrides = writeText "cinny-config-overrides.json" (builtins.toJSON conf);
+  configOverrides = writeText "${pname}-config-overrides.json" (builtins.toJSON conf);
 in
 if (conf == { }) then
   cinny-unwrapped
 else
   stdenvNoCC.mkDerivation {
-    pname = "cinny";
+    inherit pname;
     inherit (cinny-unwrapped) version meta;
 
     dontUnpack = true;
diff --git a/pkgs/by-name/sa/sable-unwrapped/package.nix b/pkgs/by-name/sa/sable-unwrapped/package.nix
new file mode 100644
index 000000000000..6cb5d792e1e4
--- /dev/null
+++ b/pkgs/by-name/sa/sable-unwrapped/package.nix
@@ -0,0 +1,80 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchPnpmDeps,
+  pnpmConfigHook,
+  pnpm_10,
+  nodejs-slim_24,
+  nix-update-script,
+}:
+
+let
+  nodejs-slim = nodejs-slim_24;
+  pnpm = pnpm_10.override { inherit nodejs-slim; };
+in
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  __darwinAllowLocalNetworking = true;
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  pname = "sable-unwrapped";
+  version = "1.19.4";
+
+  src = fetchFromGitHub {
+    owner = "SableClient";
+    repo = "Sable";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-GI4ZXmqPTWt3WlTQDkjVfRWhiJnd3mdq5paA3/TGMEA=";
+  };
+
+  pnpmDeps = fetchPnpmDeps {
+    inherit (finalAttrs) pname version src;
+    inherit pnpm;
+    fetcherVersion = 3;
+    hash = "sha256-iBvtMeYUHWhsz1DnKjTzydAt3cGPaisUhaagoaZRg1M=";
+  };
+
+  nativeBuildInputs = [
+    nodejs-slim
+    pnpmConfigHook
+    pnpm
+  ];
+
+  # Controls how the application displays its version, e.g. "v1.14.0 (nix)".
+  # Also prevents some attempts to execute git during build.
+  env = {
+    VITE_IS_RELEASE_TAG = "true";
+    VITE_BUILD_HASH = "nix";
+  };
+
+  buildPhase = ''
+    runHook preBuild
+
+    pnpm build
+
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    cp -r dist $out
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "An almost stable Matrix client";
+    homepage = "https://github.com/SableClient/Sable";
+    changelog = "https://github.com/SableClient/Sable/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.agpl3Only;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [
+      fugi
+    ];
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 40b8b3c09319..c86acad0fc96 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -9359,6 +9359,11 @@ with pkgs;
 
   rusty-psn-gui = rusty-psn.override { withGui = true; };
 
+  sable = callPackage ../by-name/ci/cinny/package.nix {
+    pname = "sable";
+    cinny-unwrapped = sable-unwrapped;
+  };
+
   sweethome3d = recurseIntoAttrs (
     (callPackage ../applications/misc/sweethome3d { })
     // (callPackage ../applications/misc/sweethome3d/editors.nix {