From 305f2d8dd46f27ba0e255268017d2e9328b62baa Mon Sep 17 00:00:00 2001
From: Sigmanificient <edhyjox@gmail.com>
Date: Sun, 9 Jun 2024 08:39:52 +0200
Subject: [PATCH] sxcs: init at 1.1.0

---
 pkgs/by-name/sx/sxcs/package.nix | 48 ++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/sx/sxcs/package.nix

diff --git a/pkgs/by-name/sx/sxcs/package.nix b/pkgs/by-name/sx/sxcs/package.nix
new file mode 100644
index 000000000000..637efb609e65
--- /dev/null
+++ b/pkgs/by-name/sx/sxcs/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  xorg,
+  installShellFiles
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  name = "sxcs";
+  version = "1.1.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "NRK";
+    repo = "sxcs";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-rYmbbdZjeLCvGvNocI3+KVU2KBkYvRisayTyScTRay8=";
+  };
+
+  buildInputs = [ xorg.libX11 xorg.libXcursor ];
+  nativeBuildInputs = [ installShellFiles ];
+
+  buildPhase = ''
+    runHook preBuild
+    ${stdenv.cc.targetPrefix}cc -o sxcs sxcs.c -O3 -s -l X11 -l Xcursor
+    runHook postBuild
+  '';
+
+  outputs = [ "out" "man" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 sxcs -t $out/bin
+    installManPage sxcs.1
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Minimal X11 Color Picker and Magnifier";
+    homepage = "https://codeberg.org/NRK/sxcs";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    platforms = lib.platforms.linux;
+  };
+})