From 9ea402c50790155e2d659fbc02d1e78f66e50e2d Mon Sep 17 00:00:00 2001
From: Florian Klink <flokli@flokli.de>
Date: Tue, 29 Apr 2025 13:12:20 +0300
Subject: [PATCH 1/2] python312Packages.ipydatawidgets: fix build

This likely regressed after bumping to numpy 2.0. Disable the two
failing tests for now, issues have been opened upstream.
---
 .../python-modules/ipydatawidgets/default.nix         | 11 +++++++++++
 1 file changed, 11 insertions(+)

diff --git a/pkgs/development/python-modules/ipydatawidgets/default.nix b/pkgs/development/python-modules/ipydatawidgets/default.nix
index cacce82794b8..bf3ff8800aab 100644
--- a/pkgs/development/python-modules/ipydatawidgets/default.nix
+++ b/pkgs/development/python-modules/ipydatawidgets/default.nix
@@ -40,6 +40,17 @@ buildPythonPackage rec {
     nbval
   ];
 
+  # Tests bind ports
+  __darwinAllowLocalNetworking = true;
+
+  pytestFlagsArray = [
+    # https://github.com/vidartf/ipydatawidgets/issues/62
+    "--deselect=ipydatawidgets/tests/test_ndarray_trait.py::test_dtype_coerce"
+
+    # https://github.com/vidartf/ipydatawidgets/issues/63
+    "--deselect=examples/test.ipynb::Cell\\\ 3"
+  ];
+
   meta = {
     description = "Widgets to help facilitate reuse of large datasets across different widgets";
     homepage = "https://github.com/vidartf/ipydatawidgets";

From b6a2debd9f944b94c0dc7a15279d3bde77957d71 Mon Sep 17 00:00:00 2001
From: Florian Klink <flokli@flokli.de>
Date: Tue, 29 Apr 2025 13:14:45 +0300
Subject: [PATCH 2/2] python312Packages.pythreejs: init at 2.4.2

---
 .../python-modules/pythreejs/default.nix      | 67 +++++++++++++++++++
 .../pythreejs/fix-re.error.patch              | 13 ++++
 pkgs/top-level/python-packages.nix            |  2 +
 3 files changed, 82 insertions(+)
 create mode 100644 pkgs/development/python-modules/pythreejs/default.nix
 create mode 100644 pkgs/development/python-modules/pythreejs/fix-re.error.patch

diff --git a/pkgs/development/python-modules/pythreejs/default.nix b/pkgs/development/python-modules/pythreejs/default.nix
new file mode 100644
index 000000000000..0ad007444f8b
--- /dev/null
+++ b/pkgs/development/python-modules/pythreejs/default.nix
@@ -0,0 +1,67 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+
+  jupyterlab,
+  setuptools,
+
+  ipywidgets,
+  ipydatawidgets,
+  numpy,
+  traitlets,
+}:
+
+buildPythonPackage rec {
+  pname = "pythreejs";
+  version = "2.4.2";
+  pyproject = true;
+
+  # github sources need to invoke npm, but no package-lock.json present:
+  # https://github.com/jupyter-widgets/pythreejs/issues/419
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-pWi/3Ew3l8TCM5FYko7cfc9vpKJnsI487FEh4geLW9Y=";
+  };
+
+  build-system = [
+    jupyterlab
+    setuptools
+  ];
+
+  # It seems pythonRelaxDeps doesn't work for these
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace-fail "jupyterlab~=" "jupyterlab>="
+
+    # https://github.com/jupyter-widgets/pythreejs/pull/420
+    substituteInPlace setupbase.py \
+      --replace-fail "import pipes" "" \
+      --replace-fail "pipes.quote" "shlex.quote"
+  '';
+
+  # Don't run npm install, all files are already where they should be present.
+  # If we would run npm install, npm would detect package-lock.json is an old format,
+  # and try to fetch more metadata from the registry, which cannot work in the sandbox.
+  setupPyBuildFlags = [ "--skip-npm" ];
+
+  dependencies = [
+    ipywidgets
+    ipydatawidgets
+    numpy
+    traitlets
+  ];
+
+  # There are no tests
+  doCheck = false;
+
+  pythonImportsCheck = [ "pythreejs" ];
+
+  meta = {
+    description = "Interactive 3D graphics for the Jupyter Notebook and JupyterLab, using Three.js and Jupyter Widgets";
+    homepage = "https://github.com/jupyter-widgets/pythreejs";
+    changelog = "https://github.com/jupyter-widgets/pythreejs/releases/tag/${version}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ flokli ];
+  };
+}
diff --git a/pkgs/development/python-modules/pythreejs/fix-re.error.patch b/pkgs/development/python-modules/pythreejs/fix-re.error.patch
new file mode 100644
index 000000000000..74e75676e7cb
--- /dev/null
+++ b/pkgs/development/python-modules/pythreejs/fix-re.error.patch
@@ -0,0 +1,13 @@
+diff --git a/setupbase.py b/setupbase.py
+index 0ce0ac8..7762e23 100644
+--- a/setupbase.py
++++ b/setupbase.py
+@@ -659,7 +659,7 @@ def _translate_glob(pat):
+         translated_parts.append(_translate_glob_part(part))
+     os_sep_class = '[%s]' % re.escape(SEPARATORS)
+     res = _join_translated(translated_parts, os_sep_class)
+-    return '{res}\\Z(?ms)'.format(res=res)
++    return '(?ms){res}\\Z'.format(res=res)
+ 
+ 
+ def _join_translated(translated_parts, os_sep_class):
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 62ba4e93a29f..bb05b2d1c6de 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -14363,6 +14363,8 @@ self: super: with self; {
 
   pythran = callPackage ../development/python-modules/pythran { inherit (pkgs.llvmPackages) openmp; };
 
+  pythreejs = callPackage ../development/python-modules/pythreejs { };
+
   pytibber = callPackage ../development/python-modules/pytibber { };
 
   pytikz-allefeld = callPackage ../development/python-modules/pytikz-allefeld { };