From 3a46f755ff10dafd7ec9a4622abb3a1d7b63fd2e Mon Sep 17 00:00:00 2001
From: Adrian Pistol <vifino@posteo.net>
Date: Tue, 21 Nov 2023 17:22:17 +0100
Subject: [PATCH 1/3] lib3270: init at 5.4

---
 pkgs/by-name/li/lib3270/package.nix | 56 +++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 pkgs/by-name/li/lib3270/package.nix

diff --git a/pkgs/by-name/li/lib3270/package.nix b/pkgs/by-name/li/lib3270/package.nix
new file mode 100644
index 000000000000..bdb74eceb282
--- /dev/null
+++ b/pkgs/by-name/li/lib3270/package.nix
@@ -0,0 +1,56 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, which
+, pkg-config
+, autoconf
+, automake
+, libtool
+, gettext
+, openssl
+, curl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "lib3270";
+  version = "5.4";
+
+  src = fetchFromGitHub {
+    owner = "PerryWerneck";
+    repo = pname;
+    rev = version;
+    hash = "sha256-w6Bg+TvSDAuZwtu/nyAIuq6pgheM5nXtfuryECfnKng=";
+  };
+
+  nativeBuildInputs = [
+    which
+    pkg-config
+    autoconf
+    automake
+    libtool
+  ];
+
+  buildInputs = [
+    gettext
+    openssl
+    curl
+  ];
+
+  postPatch = ''
+    # Patch the required version.
+    sed -i -e "s/20211118/19800101/" src/core/session.c
+  '';
+
+  preConfigure = ''
+    NOCONFIGURE=1 sh autogen.sh
+  '';
+
+  enableParallelBuilds = true;
+
+  meta = with lib; {
+    description = "TN3270 client Library";
+    homepage = "https://github.com/PerryWerneck/lib3270";
+    license = licenses.lgpl3Plus;
+    maintainers = [ maintainers.vifino ];
+  };
+}

From 5cc0c69b1df838ea5c1abbb453ffc147d70fe909 Mon Sep 17 00:00:00 2001
From: Adrian Pistol <vifino@posteo.net>
Date: Tue, 21 Nov 2023 17:27:25 +0100
Subject: [PATCH 2/3] libv3270: init at 5.4

---
 pkgs/by-name/li/libv3270/package.nix | 58 ++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/li/libv3270/package.nix

diff --git a/pkgs/by-name/li/libv3270/package.nix b/pkgs/by-name/li/libv3270/package.nix
new file mode 100644
index 000000000000..90b6fd9f2832
--- /dev/null
+++ b/pkgs/by-name/li/libv3270/package.nix
@@ -0,0 +1,58 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, autoconf
+, automake
+, libtool
+, which
+, pkg-config
+, gtk3
+, lib3270
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libv3270";
+  version = "5.4";
+
+  src = fetchFromGitHub {
+    owner = "PerryWerneck";
+    repo = pname;
+    rev = version;
+    hash = "sha256-Z3FvxPa1pfeECxfB5ZL6gwhkbTKFpfO3D/zLVLF+uiI=";
+  };
+
+  nativeBuildInputs = [
+    which
+    pkg-config
+    autoconf
+    automake
+    libtool
+  ];
+
+  buildInputs = [
+    gtk3
+    lib3270
+  ];
+
+  postPatch = ''
+    # lib3270_build_data_filename is relative to lib3270's share - not ours.
+    for f in $(find . -type f -iname "*.c"); do
+      sed -i -e "s@lib3270_build_data_filename(@g_build_filename(\"$out/share/pw3270\", @" "$f"
+    done
+  '';
+
+  preConfigure = ''
+    mkdir -p scripts
+    touch scripts/config.rpath
+    NOCONFIGURE=1 sh ./autogen.sh
+  '';
+
+  enableParallelBuilds = true;
+
+  meta = with lib; {
+    description = "3270 Virtual Terminal for GTK";
+    homepage = "https://github.com/PerryWerneck/libv3270";
+    license = licenses.lgpl3Plus;
+    maintainers = [ maintainers.vifino ];
+  };
+}

From 7f1ea97cf4e1082e52eea2be1ef6ca67d3aa2b25 Mon Sep 17 00:00:00 2001
From: Adrian Pistol <vifino@posteo.net>
Date: Tue, 21 Nov 2023 17:27:42 +0100
Subject: [PATCH 3/3] pw3270: init at 5.4

---
 pkgs/by-name/pw/pw3270/package.nix | 76 ++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 pkgs/by-name/pw/pw3270/package.nix

diff --git a/pkgs/by-name/pw/pw3270/package.nix b/pkgs/by-name/pw/pw3270/package.nix
new file mode 100644
index 000000000000..4e35f393dbcb
--- /dev/null
+++ b/pkgs/by-name/pw/pw3270/package.nix
@@ -0,0 +1,76 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, which
+, pkg-config
+, automake
+, autoconf
+, m4
+, libtool
+, gtk3
+, libv3270
+, lib3270
+, openssl
+, gettext
+, desktop-file-utils
+, glib
+, wrapGAppsHook
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pw3270";
+  version = "5.4";
+
+  src = fetchFromGitHub {
+    owner = "PerryWerneck";
+    repo = pname;
+    rev = version;
+    hash = "sha256-Nk/OUqrWngKgb1D1Wi8q5ygKtvuRKUPhPQaLvWi1Z4g=";
+  };
+
+  nativeBuildInputs = [
+    which
+    pkg-config
+    autoconf
+    automake
+    libtool
+    desktop-file-utils
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk3
+    gettext
+    libv3270
+    lib3270
+    openssl
+  ];
+
+  postPatch = ''
+    # lib3270_build_data_filename is relative to lib3270's share - not ours.
+    for f in $(find . -type f -iname "*.c"); do
+      sed -i -e "s@lib3270_build_data_filename(@g_build_filename(\"$out/share/pw3270\", @" "$f"
+    done
+  '';
+
+  preConfigure = ''
+    NOCONFIGURE=1 sh autogen.sh
+  '';
+
+  postFixup = ''
+    # Schemas get installed to wrong directory.
+    mkdir -p $out/share/glib-2.0
+    mv $out/share/gsettings-schemas/${pname}-${version}/glib-2.0/schemas $out/share/glib-2.0/
+    rm -rf $out/share/gsettings-schemas
+  '';
+
+  enableParallelBuilds = true;
+
+  meta = with lib; {
+    description = "3270 Emulator for gtk";
+    homepage = "https://softwarepublico.gov.br/social/pw3270/";
+    license = licenses.lgpl3Plus;
+    maintainers = [ maintainers.vifino ];
+    mainProgram = "pw3270";
+  };
+}