From edc1ab046eb34d122315ea27de413237744c19a3 Mon Sep 17 00:00:00 2001
From: John Mark Gabriel Caguicla <jmg.caguicla@guarandoo.me>
Date: Thu, 26 Jun 2025 20:14:00 +0800
Subject: [PATCH 1/2] maintainer: add caguiclajmg

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index d44936743b44..747f6ab0391b 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -4006,6 +4006,12 @@
       { fingerprint = "8916 F727 734E 77AB 437F  A33A 19AB 76F5 CEE1 1392"; }
     ];
   };
+  caguiclajmg = {
+    email = "jmg.caguicla@guarandoo.me";
+    github = "caguiclajmg";
+    githubId = 32662060;
+    name = "John Mark Gabriel Caguicla";
+  };
   CaiqueFigueiredo = {
     email = "public@caiquefigueiredo.me";
     github = "caiquefigueiredo";

From 6212eaa047ecbe9a52b35547b47b8392734dc0e0 Mon Sep 17 00:00:00 2001
From: John Mark Gabriel Caguicla <jmg.caguicla@guarandoo.me>
Date: Thu, 26 Jun 2025 20:08:49 +0800
Subject: [PATCH 2/2] epson_202101w: init at 1.0.2

---
 pkgs/by-name/ep/epson-202101w/package.nix | 92 +++++++++++++++++++++++
 1 file changed, 92 insertions(+)
 create mode 100644 pkgs/by-name/ep/epson-202101w/package.nix

diff --git a/pkgs/by-name/ep/epson-202101w/package.nix b/pkgs/by-name/ep/epson-202101w/package.nix
new file mode 100644
index 000000000000..53c2c0a969f5
--- /dev/null
+++ b/pkgs/by-name/ep/epson-202101w/package.nix
@@ -0,0 +1,92 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  rpmextract,
+  autoreconfHook,
+  autoPatchelfHook,
+  file,
+  libjpeg,
+  cups,
+}:
+
+let
+  version = "1.0.2";
+in
+stdenv.mkDerivation {
+  pname = "epson-202101w";
+  inherit version;
+
+  __structuredAttrs = true;
+  strictDeps = true;
+
+  src = fetchurl {
+    # NOTE: Don't forget to update the webarchive link too!
+    urls = [
+      "https://download3.ebz.epson.net/dsc/f/03/00/15/15/02/f5cba2761f2f501363cdbf7e1b9b9879b0715aa5/epson-inkjet-printer-202101w-1.0.2-1.src.rpm"
+      "https://web.archive.org/web/20250609030209if_/https://download3.ebz.epson.net/dsc/f/03/00/15/15/02/f5cba2761f2f501363cdbf7e1b9b9879b0715aa5/epson-inkjet-printer-202101w-1.0.2-1.src.rpm"
+    ];
+    sha256 = "17lz5cccknabp8cbkplhv1sn92m5w5md01rhhycbngp10zdmyhcz";
+  };
+
+  nativeBuildInputs = [
+    rpmextract
+    autoreconfHook
+    autoPatchelfHook
+    file
+  ];
+
+  buildInputs = [
+    libjpeg
+    cups
+    (lib.getLib stdenv.cc.cc)
+  ];
+
+  unpackPhase = ''
+    rpmextract $src
+    tar -zxf epson-inkjet-printer-202101w-${version}.tar.gz
+    tar -zxf epson-inkjet-printer-filter-${version}.tar.gz
+    for ppd in epson-inkjet-printer-202101w-${version}/ppds/*; do
+      substituteInPlace $ppd --replace "/opt/epson-inkjet-printer-202101w" "$out"
+      substituteInPlace $ppd --replace "/cups/lib" "/lib/cups"
+    done
+    cd epson-inkjet-printer-filter-${version}
+  '';
+
+  preConfigure = ''
+    chmod +x configure
+  '';
+
+  postInstall = ''
+    cd ../epson-inkjet-printer-202101w-${version}
+    cp -a lib64 resource watermark $out
+    mkdir -p $out/share/cups/model/epson-inkjet-printer-202101w
+    cp -a ppds $out/share/cups/model/epson-inkjet-printer-202101w/
+    cp -a Manual.txt $out/doc/
+    cp -a README $out/doc/README.driver
+  '';
+
+  meta = {
+    homepage = "https://www.openprinting.org/driver/epson-202101w";
+    description = "Epson printer driver (L1210, L1250, L3200, L3210)";
+    longDescription = ''
+      This software is a filter program used with the Common UNIX Printing
+      System (CUPS) under Linux. It supplies high quality printing with
+      Seiko Epson Color Ink Jet Printers.
+
+      To use the driver adjust your configuration.nix file:
+        services.printing = {
+          enable = true;
+          drivers = [ pkgs.epson-202101w ];
+        };
+    '';
+    license = with lib.licenses; [
+      lgpl21
+      epson
+    ];
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      caguiclajmg
+    ];
+  };
+}