From f2d6afbb926517e1101e17db1682d075da80745f Mon Sep 17 00:00:00 2001
From: AveryanAlex <alex@averyan.ru>
Date: Fri, 12 Jul 2024 01:22:10 +0300
Subject: [PATCH] nwg-clipman: init at 0.2.3

---
 pkgs/by-name/nw/nwg-clipman/package.nix | 68 +++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 pkgs/by-name/nw/nwg-clipman/package.nix

diff --git a/pkgs/by-name/nw/nwg-clipman/package.nix b/pkgs/by-name/nw/nwg-clipman/package.nix
new file mode 100644
index 000000000000..2db08263729a
--- /dev/null
+++ b/pkgs/by-name/nw/nwg-clipman/package.nix
@@ -0,0 +1,68 @@
+{
+  lib,
+  fetchFromGitHub,
+  python3Packages,
+  gobject-introspection,
+  wrapGAppsHook3,
+  gtk-layer-shell,
+  gtk3,
+  wl-clipboard,
+  cliphist,
+  nix-update-script,
+}:
+
+python3Packages.buildPythonPackage rec {
+  pname = "nwg-clipman";
+  version = "0.2.3";
+
+  src = fetchFromGitHub {
+    owner = "nwg-piotr";
+    repo = "nwg-clipman";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-qpI/yg7yBSwcgpv6lOBysxxsX0pI+ixZghkm+U6XIrs=";
+  };
+
+  build-system = [ python3Packages.setuptools ];
+
+  nativeBuildInputs = [
+    gobject-introspection
+    wrapGAppsHook3
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+  buildInputs = [
+    gtk-layer-shell
+    gtk3
+  ];
+
+  dependencies = with python3Packages; [ pygobject3 ];
+
+  nativeCheckInputs = [
+    wl-clipboard
+    cliphist
+  ];
+
+  postInstall = ''
+    install -Dm644 nwg-clipman.desktop -t $out/share/applications/
+    install -Dm644 nwg-clipman.svg -t $out/share/pixmaps/
+  '';
+
+  strictDeps = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "GTK3-based GUI for cliphist";
+    homepage = "https://github.com/nwg-piotr/nwg-clipman";
+    changelog = "https://github.com/nwg-piotr/nwg-clipman/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ averyanalex ];
+    platforms = lib.platforms.linux;
+    mainProgram = "nwg-clipman";
+  };
+}