From a7493a6a7c864bbbb4289eac321db7841a74b433 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Th=C3=A9o=20Bori?= <theo1.bori@epitech.eu>
Date: Sun, 2 Feb 2025 19:09:17 +0100
Subject: [PATCH] pdftricks: init at 0.4.1

---
 pkgs/by-name/pd/pdftricks/package.nix | 68 +++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 pkgs/by-name/pd/pdftricks/package.nix

diff --git a/pkgs/by-name/pd/pdftricks/package.nix b/pkgs/by-name/pd/pdftricks/package.nix
new file mode 100644
index 000000000000..4ad66a2ff843
--- /dev/null
+++ b/pkgs/by-name/pd/pdftricks/package.nix
@@ -0,0 +1,68 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  pkg-config,
+  vala,
+  gtk3,
+  wrapGAppsHook3,
+  pantheon,
+  ninja,
+  ghostscript,
+  makeWrapper,
+  nix-update-script,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "pdftricks";
+  version = "0.4.1";
+
+  src = fetchFromGitHub {
+    owner = "muriloventuroso";
+    repo = "pdftricks";
+    tag = finalAttrs.version;
+    hash = "sha256-l4Xg4Uk520qoaEo8UxdLE8MfpVkRj/bpGBzL5HwdDUo=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    pkg-config
+    vala
+    wrapGAppsHook3
+    ninja
+    makeWrapper
+  ];
+
+  buildInputs = [
+    gtk3
+    pantheon.granite
+    ghostscript
+  ];
+
+  preFixup = ''
+    wrapProgram $out/bin/com.github.muriloventuroso.pdftricks \
+      --prefix PATH : ${lib.makeBinPath [ ghostscript ]} \
+      ''${gappsWrapperArgs[@]}
+  '';
+
+  dontWrapGApps = true;
+
+  postPatch = ''
+    # Remove positional arguments that cause errors
+    substituteInPlace data/meson.build \
+      --replace-fail "'desktop'," "" \
+      --replace-fail "'appdata'," ""
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Simple, efficient application for small manipulations in PDF files using Ghostscript";
+    homepage = "https://github.com/muriloventuroso/pdftricks";
+    changelog = "https://github.com/muriloventuroso/pdftricks/releases";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ theobori ];
+    platforms = lib.platforms.linux;
+    mainProgram = "com.github.muriloventuroso.pdftricks";
+  };
+})