From 7ea1e9bc89bf96d5c19a5086df973357f61dde4c Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:54:39 +0200
Subject: [PATCH 1/3] rapidapi: init at 4.2.8-4002008002

---
 pkgs/by-name/ra/rapidapi/package.nix | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/ra/rapidapi/package.nix

diff --git a/pkgs/by-name/ra/rapidapi/package.nix b/pkgs/by-name/ra/rapidapi/package.nix
new file mode 100644
index 000000000000..0fc54f7c0735
--- /dev/null
+++ b/pkgs/by-name/ra/rapidapi/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  unzip,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "rapidapi";
+  version = "4.2.8-4002008002";
+
+  src = fetchurl {
+    url = "https://cdn-builds.paw.cloud/paw/RapidAPI-${finalAttrs.version}.zip";
+    hash = "sha256-ApBOYMOjpQJvUe+JsEAnyK7xpIZNt6qkX/2KUIT6S8g=";
+  };
+
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  dontFixup = true;
+  dontUnpack = true;
+
+  nativeBuildInputs = [ unzip ];
+
+  sourceRoot = "RapidAPI.app";
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/Applications
+    unzip -d $out/Applications $src
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Full-featured HTTP client that lets you test and describe the APIs you build or consume";
+    homepage = "https://paw.cloud";
+    changelog = "https://paw.cloud/updates/${lib.head (lib.splitString "-" finalAttrs.version)}";
+    license = lib.licenses.unfree;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    maintainers = with lib.maintainers; [ DimitarNestorov ];
+    platforms = [
+      "aarch64-darwin"
+      "x86_64-darwin"
+    ];
+  };
+})

From 092ea5b1ad3d6543af6d329a50fc21234d76bce2 Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:54:39 +0200
Subject: [PATCH 2/3] rapidapi: add update script

---
 pkgs/by-name/ra/rapidapi/package.nix | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)

diff --git a/pkgs/by-name/ra/rapidapi/package.nix b/pkgs/by-name/ra/rapidapi/package.nix
index 0fc54f7c0735..9f7f6f79948e 100644
--- a/pkgs/by-name/ra/rapidapi/package.nix
+++ b/pkgs/by-name/ra/rapidapi/package.nix
@@ -3,6 +3,11 @@
   stdenvNoCC,
   fetchurl,
   unzip,
+  writeShellApplication,
+  curl,
+  cacert,
+  gnugrep,
+  common-updater-scripts,
 }:
 
 stdenvNoCC.mkDerivation (finalAttrs: {
@@ -33,6 +38,21 @@ stdenvNoCC.mkDerivation (finalAttrs: {
     runHook postInstall
   '';
 
+  passthru.updateScript = lib.getExe (writeShellApplication {
+    name = "rapidapi-update-script";
+    runtimeInputs = [
+      curl
+      cacert
+      gnugrep
+      common-updater-scripts
+    ];
+    text = ''
+      url="https://paw.cloud/download"
+      version=$(curl -Ls -o /dev/null -w "%{url_effective}" "$url" | grep -oP '\d+\.\d+\.\d+-\d+')
+      update-source-version rapidapi "$version"
+    '';
+  });
+
   meta = {
     description = "Full-featured HTTP client that lets you test and describe the APIs you build or consume";
     homepage = "https://paw.cloud";

From b8a273f71123f920dcaf4015a490c977674b7256 Mon Sep 17 00:00:00 2001
From: Dimitar Nestorov <8790386+dimitarnestorov@users.noreply.github.com>
Date: Sun, 12 Jan 2025 21:54:39 +0200
Subject: [PATCH 3/3] rapidapi: add version check

---
 pkgs/by-name/ra/rapidapi/package.nix | 13 +++++++++++++
 1 file changed, 13 insertions(+)

diff --git a/pkgs/by-name/ra/rapidapi/package.nix b/pkgs/by-name/ra/rapidapi/package.nix
index 9f7f6f79948e..108197375beb 100644
--- a/pkgs/by-name/ra/rapidapi/package.nix
+++ b/pkgs/by-name/ra/rapidapi/package.nix
@@ -8,6 +8,10 @@
   cacert,
   gnugrep,
   common-updater-scripts,
+  versionCheckHook,
+  writeShellScript,
+  xcbuild,
+  coreutils,
 }:
 
 stdenvNoCC.mkDerivation (finalAttrs: {
@@ -53,6 +57,15 @@ stdenvNoCC.mkDerivation (finalAttrs: {
     '';
   });
 
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgram = writeShellScript "version-check" ''
+    marketing_version=$(${xcbuild}/bin/PlistBuddy -c "Print :CFBundleShortVersionString" "$1" | ${coreutils}/bin/tr -d '"')
+    build_version=$(${xcbuild}/bin/PlistBuddy -c "Print :CFBundleVersion" "$1")
+    echo $marketing_version-$build_version
+  '';
+  versionCheckProgramArg = [ "${placeholder "out"}/Applications/RapidAPI.app/Contents/Info.plist" ];
+  doInstallCheck = true;
+
   meta = {
     description = "Full-featured HTTP client that lets you test and describe the APIs you build or consume";
     homepage = "https://paw.cloud";