{cardboard,nixos/cardboard}: drop (#447042)

nixos/doc/manual/release-notes/rl-2511.section.md

@@ -176,6 +176,8 @@
 
 - `programs.goldwarden` has been removed, due to the software not working with newer versions of the Bitwarden and Vaultwarden servers, as well as it being abandoned upstream.
 
+- The `cardboard` package and `programs.cardboard` module were removed due to the package having been broken since at least November 2024.
+
 - The default `kops` version is now 1.33.0 and versions 1.30 and older have been dropped. See [Upgrading Kubernetes](https://kops.sigs.k8s.io/tutorial/upgrading-kubernetes/) for instructions on how to update kOps.
 
 - `programs.skim.fuzzyCompletions` has been removed in favor of adding the completions to the package itself.

nixos/modules/module-list.nix

@@ -337,7 +337,6 @@
   ./programs/vivid.nix
   ./programs/vscode.nix
   ./programs/wavemon.nix
-  ./programs/wayland/cardboard.nix
   ./programs/wayland/dwl.nix
   ./programs/wayland/gtklock.nix
   ./programs/wayland/hyprland.nix

nixos/modules/programs/wayland/cardboard.nix

@@ -1,31 +0,0 @@
-{
-  config,
-  lib,
-  pkgs,
-  ...
-}:
-
-let
-  cfg = config.programs.cardboard;
-in
-{
-  meta.maintainers = with lib.maintainers; [ ];
-
-  options.programs.cardboard = {
-    enable = lib.mkEnableOption "cardboard";
-
-    package = lib.mkPackageOption pkgs "cardboard" { };
-  };
-
-  config = lib.mkIf cfg.enable (
-    lib.mkMerge [
-      {
-        environment.systemPackages = [ cfg.package ];
-
-        # To make a cardboard session available for certain DMs like SDDM
-        services.displayManager.sessionPackages = [ cfg.package ];
-      }
-      (import ./wayland-session.nix { inherit lib pkgs; })
-    ]
-  );
-}

nixos/modules/rename.nix

@@ -58,6 +58,10 @@ in
       "networking"
       "wicd"
     ] "The corresponding package was removed from nixpkgs.")
+    (mkRemovedOptionModule [
+      "programs"
+      "cardboard"
+    ] "The corresponding package was removed from nixpkgs.")
     (mkRemovedOptionModule [
       "programs"
       "gnome-documents"

pkgs/by-name/ca/cardboard/package.nix

@@ -1,146 +0,0 @@
-{
-  lib,
-  stdenv,
-  fetchFromGitLab,
-  fetchurl,
-  fetchgit,
-  ffmpeg,
-  libGL,
-  libX11,
-  libcap,
-  libdrm,
-  libinput,
-  libpng,
-  libxcb,
-  libxkbcommon,
-  libgbm,
-  meson,
-  ninja,
-  pandoc,
-  pixman,
-  pkg-config,
-  unzip,
-  wayland,
-  wayland-protocols,
-  wayland-scanner,
-  xcbutilerrors,
-  xcbutilimage,
-  xcbutilwm,
-}:
-
-let
-  allSources = {
-    # cereal.wrap
-    cereal-wrap = fetchurl {
-      name = "cereal-1.3.0.tar.gz";
-      url = "https://github.com/USCiLab/cereal/archive/v1.3.0.tar.gz";
-      hash = "sha256-Mp6j4xMLAmwDpKzFDhaOfa/05uZhvGp9/sDXe1cIUdU=";
-    };
-    cereal-wrapdb = fetchurl {
-      name = "cereal-1.3.0-1-wrap.zip";
-      url = "https://wrapdb.mesonbuild.com/v1/projects/cereal/1.3.0/1/get_zip";
-      hash = "sha256-QYck5UT7fPLqtLDb1iOSX4Hnnns48Jj23Ae/LCfLSKY=";
-    };
-
-    # expected.wrap
-    expected-wrap = fetchgit {
-      name = "expected";
-      url = "https://gitlab.com/cardboardwm/expected";
-      rev = "0ee13cb2b058809aa9708c45ca18d494e72a759e";
-      hash = "sha256-gYr4/pjuLlr3k6Jcrg2/SzJLtbgyA+ZN2oMHkHXANDo=";
-    };
-
-    # wlroots.wrap
-    wlroots-wrap = fetchgit {
-      name = "wlroots";
-      url = "https://github.com/swaywm/wlroots";
-      rev = "0.12.0";
-      hash = "sha256-1rE3D+kQprjcjobc95/mQkUa5y1noY0MdoYJ/SpFQwY=";
-    };
-
-    # the source itself
-    cardboard = fetchFromGitLab {
-      owner = "cardboardwm";
-      repo = "cardboard";
-      rev = "b54758d85164fb19468f5ca52588ebea576cd027";
-      hash = "sha256-Kn5NyQSDyX7/nn2bKZPnsuepkoppi5XIkdu7IDy5r4w=";
-    };
-  };
-in
-stdenv.mkDerivation {
-  pname = "cardboard";
-  version = "unstable-2021-05-10";
-
-  src = allSources.cardboard;
-
-  outputs = [
-    "out"
-    "dev"
-    "lib"
-    "man"
-  ];
-
-  nativeBuildInputs = [
-    meson
-    ninja
-    pandoc
-    pkg-config
-    unzip
-    wayland-scanner
-  ];
-
-  buildInputs = [
-    ffmpeg
-    libGL
-    libX11
-    libcap
-    libdrm
-    libinput
-    libpng
-    libxcb
-    libxkbcommon
-    libgbm
-    pixman
-    wayland
-    wayland-protocols
-    xcbutilerrors
-    xcbutilimage
-    xcbutilwm
-  ];
-
-  postPatch = ''
-    pushd subprojects
-    tar xvf ${allSources.cereal-wrap}
-    unzip ${allSources.cereal-wrapdb}
-    cp -r ${allSources.expected-wrap} ${allSources.expected-wrap.name}
-    cp -r ${allSources.wlroots-wrap} ${allSources.wlroots-wrap.name}
-    popd
-
-    # gcc12
-    sed '1i#include <functional>' -i cardboard/ViewAnimation.h
-  '';
-
-  # "Inherited" from Nixpkgs expression for wlroots
-  mesonFlags = [
-    (lib.mesonBool "man" true)
-    (lib.mesonOption "wlroots:logind-provider" "systemd")
-    (lib.mesonEnable "wlroots:libseat" false)
-  ];
-
-  # gcc12
-  env.NIX_CFLAGS_COMPILE = toString [ "-Wno-error=array-bounds" ];
-
-  passthru = {
-    providedSessions = [ "cardboard" ];
-  };
-
-  meta = {
-    broken = true; # Upstream is archived, fails to build on gcc-13.
-    homepage = "https://gitlab.com/cardboardwm/cardboard";
-    description = "Scrollable, tiling Wayland compositor inspired on PaperWM";
-    license = lib.licenses.gpl3Only;
-    mainProgram = "cardboard";
-    maintainers = with lib.maintainers; [ ];
-    inherit (wayland.meta) platforms;
-  };
-}

pkgs/top-level/aliases.nix

@@ -580,6 +580,7 @@ mapAliases {
   cask = emacs.pkgs.cask; # Added 2022-11-12
   catcli = throw "catcli has been superseded by gocatcli"; # Added 2025-04-19
   canonicalize-jars-hook = stripJavaArchivesHook; # Added 2024-03-17
+  cardboard = throw "cardboard has been removed because it has been marked as broken since at least November 2024."; # Added 2025-09-28
   cargo-deps = throw "cargo-deps has been removed as the repository is deleted"; # Added 2024-04-09
   cargo-espflash = espflash; # Added 2024-02-09
   cargo-kcov = throw "'cargo-kcov' has been removed due to lack of upstream maintenance"; # Added 2025-01-25