From 1d22eb4b227c3453571224dd0d4fe45f7158693c Mon Sep 17 00:00:00 2001
From: Matthias Beyer <mail@beyermatthias.de>
Date: Sat, 24 Jan 2026 12:10:11 +0100
Subject: [PATCH] whosthere: init at 0.2.1

Signed-off-by: Matthias Beyer <mail@beyermatthias.de>
---
 pkgs/by-name/wh/whosthere/package.nix | 49 +++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 pkgs/by-name/wh/whosthere/package.nix

diff --git a/pkgs/by-name/wh/whosthere/package.nix b/pkgs/by-name/wh/whosthere/package.nix
new file mode 100644
index 000000000000..ce799e938efa
--- /dev/null
+++ b/pkgs/by-name/wh/whosthere/package.nix
@@ -0,0 +1,49 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  testers,
+  whosthere,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "whosthere";
+  version = "0.2.1";
+
+  src = fetchFromGitHub {
+    owner = "ramonvermeulen";
+    repo = "whosthere";
+    tag = "v${finalAttrs.version}";
+    sha256 = "sha256-jwXJ+mF3r+Xg3lyQzwzfGp3TmfVjnxO9Lg272zeTREY=";
+  };
+
+  vendorHash = "sha256-ZiomQ+Md0kFkq7nERsnLZwkA9nlcvglMtzJV7NX3Igs=";
+
+  checkFlags =
+    let
+      # Skip tests that require filesystem access
+      skippedTests = [
+        "TestResolveLogPath"
+        "TestStateDir"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  passthru.updateScript = nix-update-script { };
+  passthru.tests.version = testers.testVersion { package = whosthere; };
+
+  meta = {
+    description = "Local Area Network discovery tool";
+    longDescription = ''
+      Local Area Network discovery tool with a modern Terminal User Interface
+      (TUI) written in Go. Discover, explore, and understand your LAN in an
+      intuitive way. Knock Knock.. who's there?
+    '';
+    homepage = "https://github.com/ramonvermeulen/whosthere";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ matthiasbeyer ];
+    platforms = lib.platforms.linux;
+    mainProgram = "whosthere";
+  };
+})