From 1b89d0a9cbc1e6feffe6c0d3dc976e50cc4603f0 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Sandro=20J=C3=A4ckel?= <sandro.jaeckel@gmail.com>
Date: Wed, 30 Mar 2022 15:38:43 +0200
Subject: [PATCH] join-desktop: init at 1.1.2

---
 .../misc/join-desktop/default.nix             | 73 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 75 insertions(+)
 create mode 100644 pkgs/applications/misc/join-desktop/default.nix

diff --git a/pkgs/applications/misc/join-desktop/default.nix b/pkgs/applications/misc/join-desktop/default.nix
new file mode 100644
index 000000000000..0b09911ddb24
--- /dev/null
+++ b/pkgs/applications/misc/join-desktop/default.nix
@@ -0,0 +1,73 @@
+{ lib
+, stdenv
+, fetchurl
+, alsa-lib
+, autoPatchelfHook
+, dpkg
+, gtk3
+, makeWrapper
+, mesa
+, nss
+, systemd
+, xorg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "join-desktop";
+  version = "1.1.2";
+
+  src = fetchurl {
+    url = "https://github.com/joaomgcd/JoinDesktop/releases/download/v${version}/com.joaomgcd.join_${version}_amd64.deb";
+    sha256 = "sha256-k1LX/HC3tfL4Raipo7wp/LnfrPa38x8NBeKRyHJ72CU=";
+  };
+
+  nativeBuildInputs = [
+    autoPatchelfHook
+    dpkg
+    makeWrapper
+  ];
+
+  buildInputs = [
+    alsa-lib
+    gtk3
+    mesa
+    nss
+    xorg.libXScrnSaver
+    xorg.libXtst
+  ];
+
+  unpackPhase = "dpkg-deb -x $src .";
+
+  runtimeDependencies = [
+    (lib.getLib systemd)
+    # TODO: check if they are required
+    # libnotify
+    # libappindicator
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/bin $out/share/join-desktop
+
+    mv usr/share/* $out/share
+    mv opt/Join\ Desktop/* $out/share/join-desktop
+
+    ln -s $out/share/join-desktop/com.joaomgcd.join $out/bin/
+
+    substituteInPlace $out/share/applications/com.joaomgcd.join.desktop \
+      --replace "/opt/Join Desktop/com.joaomgcd.join" "com.joaomgcd.join"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/joaomgcd/JoinDesktop/";
+    description = "Desktop app for Join";
+    # on https://joaoapps.com/join/desktop/ "Join Desktop is an open source app" but no license
+    license = licenses.free;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ SuperSandro2000 ];
+  };
+
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b12158d94bc7..44c59788c6c4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -24863,6 +24863,8 @@ with pkgs;
 
   jnetmap = callPackage ../applications/networking/jnetmap {};
 
+  join-desktop = callPackage ../applications/misc/join-desktop { };
+
   libbitcoin = callPackage ../tools/misc/libbitcoin/libbitcoin.nix {
     boost = boost175; # fatal error: 'boost/interprocess/detail/posix_time_types_wrk.hpp' file not found
   };