From 1b040dd91b153e1e5af23b1e62d9aaa49f9bf2f2 Mon Sep 17 00:00:00 2001
From: John Titor <50095635+JohnRTitor@users.noreply.github.com>
Date: Mon, 17 Mar 2025 18:35:23 +0530
Subject: [PATCH] altus: init at 5.6.0

Altus is a Desktop client for WhatsApp Web with themes, notifications and multiple account support.
Link: https://github.com/amanharwara/altus

Signed-off-by: John Titor <50095635+JohnRTitor@users.noreply.github.com>
---
 pkgs/by-name/al/altus/package.nix | 45 +++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 pkgs/by-name/al/altus/package.nix

diff --git a/pkgs/by-name/al/altus/package.nix b/pkgs/by-name/al/altus/package.nix
new file mode 100644
index 000000000000..59eb2e510921
--- /dev/null
+++ b/pkgs/by-name/al/altus/package.nix
@@ -0,0 +1,45 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+  makeWrapper,
+}:
+
+let
+  pname = "altus";
+  version = "5.6.0";
+
+  src = fetchurl {
+    name = "altus-${version}.AppImage";
+    url = "https://github.com/amanharwara/altus/releases/download/${version}/Altus-${version}.AppImage";
+    hash = "sha512-u4eBTboFJaU5qLFURXFchOmFV7GzlDbUokrBpxx8QeAJO6B0IwX1gJU0C69BKinIdO4Q93SAcjsvUkvSI+blrw==";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit pname version src;
+  };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  extraInstallCommands = ''
+    install -m 444 -D ${appimageContents}/Altus.desktop $out/share/applications/altus.desktop
+    install -m 444 -D ${appimageContents}/Altus.png \
+      $out/share/icons/hicolor/scalable/apps/altus.png
+    substituteInPlace $out/share/applications/altus.desktop \
+      --replace-fail 'Exec=AppRun' 'Exec=altus'
+    wrapProgram "$out/bin/altus" \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations --enable-wayland-ime=true}}"
+  '';
+
+  meta = {
+    description = "Client for WhatsApp Web with themes, notifications and multiple accounts support";
+    homepage = "https://github.com/amanharwara/altus";
+    changelog = "https://github.com/amanharwara/altus/releases/tag/v${version}";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ johnrtitor ];
+    platforms = [ "x86_64-linux" ];
+  };
+}