From 5d580a39ed794372b9c4045e263b528059b2bf51 Mon Sep 17 00:00:00 2001
From: Sam Willcocks <sam@wlcx.cc>
Date: Sun, 15 Dec 2024 23:54:28 +0000
Subject: [PATCH] openterface-qt: init at 0.0.6

---
 pkgs/by-name/op/openterface-qt/package.nix | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 pkgs/by-name/op/openterface-qt/package.nix

diff --git a/pkgs/by-name/op/openterface-qt/package.nix b/pkgs/by-name/op/openterface-qt/package.nix
new file mode 100644
index 000000000000..86c13c0bc70e
--- /dev/null
+++ b/pkgs/by-name/op/openterface-qt/package.nix
@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  makeDesktopItem,
+  copyDesktopItems,
+  fetchFromGitHub,
+  qt6,
+  libusb1,
+}:
+stdenv.mkDerivation (final: {
+  pname = "openterface-qt";
+  version = "0.0.6";
+  src = fetchFromGitHub {
+    owner = "TechxArtisanStudio";
+    repo = "Openterface_QT";
+    rev = "v${final.version}";
+    hash = "sha256-orSOEzyplV0d+faaaRpXeMOhwbnOFxir7DG3LdErCdI=";
+  };
+  nativeBuildInputs = [
+    copyDesktopItems
+    qt6.wrapQtAppsHook
+    qt6.qmake
+  ];
+  buildInputs = [
+    libusb1
+    qt6.qtbase
+    qt6.qtmultimedia
+    qt6.qtserialport
+    qt6.qtsvg
+  ];
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp ./openterfaceQT $out/bin/
+    mkdir -p $out/share/pixmaps
+    cp ./images/icon_256.png $out/share/pixmaps/${final.pname}.png
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "openterfaceQT";
+      exec = "openterfaceQT";
+      icon = final.pname;
+      comment = final.meta.description;
+      desktopName = "Openterface QT";
+      categories = [ "Utility" ];
+    })
+  ];
+
+  meta = {
+    description = "Openterface mini-KVM host application for linux";
+    homepage = "https://github.com/TechxArtisanStudio/Openterface_QT";
+    license = lib.licenses.agpl3Only;
+    mainProgram = "openterfaceQT";
+    maintainers = with lib.maintainers; [ samw ];
+    platforms = lib.platforms.linux;
+  };
+})