From 146fb01d7d7791f9448f8375f8941da715a1ebd6 Mon Sep 17 00:00:00 2001
From: Nazar Vinnichuk <nazar@vinnich.uk>
Date: Fri, 27 Mar 2026 20:23:55 +0200
Subject: [PATCH] python3Packages.synchronicity: init at 0.11.1

---
 .../python-modules/synchronicity/default.nix  | 63 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 65 insertions(+)
 create mode 100644 pkgs/development/python-modules/synchronicity/default.nix

diff --git a/pkgs/development/python-modules/synchronicity/default.nix b/pkgs/development/python-modules/synchronicity/default.nix
new file mode 100644
index 000000000000..1509b56d96db
--- /dev/null
+++ b/pkgs/development/python-modules/synchronicity/default.nix
@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  fetchFromGitHub,
+  gevent,
+  hatchling,
+  mypy,
+  pytest-asyncio,
+  pytest-markdown-docs,
+  pytestCheckHook,
+  pythonOlder,
+  sigtools,
+  typing-extensions,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "synchronicity";
+  version = "0.11.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "modal-labs";
+    repo = "synchronicity";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-Uyn4apHILBwjHoMkr52IkcFlaX7jx3WzuzZfvdxcDFo=";
+  };
+
+  build-system = [ hatchling ];
+  dependencies = [ typing-extensions ];
+  optional-dependencies.compile = [ sigtools ];
+
+  nativeCheckInputs = [
+    mypy
+    pytestCheckHook
+    pytest-asyncio
+    pytest-markdown-docs
+    sigtools
+  ]
+  ++ lib.optionals (pythonOlder "3.13") [
+    gevent
+  ];
+
+  disabledTests = [
+    # Assert execution time, non-deterministic
+    "test_blocking"
+    "test_multithreaded"
+    "test_nowrap"
+  ]
+  ++ lib.optionals stdenv.hostPlatform.isDarwin [
+    # Assertion error
+    "test_async"
+  ];
+
+  pythonImportsCheck = [ "synchronicity" ];
+
+  meta = {
+    description = "Export blocking and async library versions from a single async implementation";
+    homepage = "https://github.com/modal-labs/synchronicity";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ Kharacternyk ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index c100206eae07..ed9eb35aa310 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -18825,6 +18825,8 @@ self: super: with self; {
 
   syncer = callPackage ../development/python-modules/syncer { };
 
+  synchronicity = callPackage ../development/python-modules/synchronicity { };
+
   syndication-domination = toPythonModule (
     pkgs.syndication-domination.override {
       enablePython = true;