From 127ee2dce6bbda65504dc4519a598ff27be05aa5 Mon Sep 17 00:00:00 2001
From: rewine <luhongxu@deepin.org>
Date: Thu, 26 Sep 2024 21:25:56 +0800
Subject: [PATCH] deepin.qt6mpris: init at 1.0.0.1-1deepin1

---
 pkgs/desktops/deepin/default.nix              |  1 +
 .../deepin/library/qt6mpris/default.nix       | 46 +++++++++++++++++++
 2 files changed, 47 insertions(+)
 create mode 100644 pkgs/desktops/deepin/library/qt6mpris/default.nix

diff --git a/pkgs/desktops/deepin/default.nix b/pkgs/desktops/deepin/default.nix
index fc8137cac857..4b350abdd1a7 100644
--- a/pkgs/desktops/deepin/default.nix
+++ b/pkgs/desktops/deepin/default.nix
@@ -38,6 +38,7 @@ let
       dtk6log = callPackage ./library/dtk6log { };
       qt6platform-plugins = callPackage ./library/qt6platform-plugins { };
       qt6integration = callPackage ./library/qt6integration { };
+      qt6mpris = callPackage ./library/qt6mpris { };
 
       #### CORE
       deepin-kwin = callPackage ./core/deepin-kwin { };
diff --git a/pkgs/desktops/deepin/library/qt6mpris/default.nix b/pkgs/desktops/deepin/library/qt6mpris/default.nix
new file mode 100644
index 000000000000..71a17256d6c1
--- /dev/null
+++ b/pkgs/desktops/deepin/library/qt6mpris/default.nix
@@ -0,0 +1,46 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  qt6Packages,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qt6mpris";
+  version = "1.0.0.1-1deepin1";
+
+  src = fetchFromGitHub {
+    owner = "deepin-community";
+    repo = "qt6mpris";
+    rev = finalAttrs.version;
+    hash = "sha256-PCdA9q/txaL2Fbr2/4+Z7L4zxWeULl3bq8MVH3i1g3g=";
+  };
+
+  postPatch = ''
+    substituteInPlace src/src.pro \
+      --replace-fail '$$[QT_INSTALL_LIBS]'    "$out/lib" \
+      --replace-fail '$$[QT_INSTALL_HEADERS]' "$out/include" \
+      --replace-fail '$$[QMAKE_MKSPECS]'      "$out/mkspecs"
+    substituteInPlace declarative/declarative.pro \
+      --replace-fail '$$[QT_INSTALL_QML]'     "$out/${qt6Packages.qtbase.qtQmlPrefix}"
+  '';
+
+  nativeBuildInputs = [
+    qt6Packages.qmake
+  ];
+
+  dontWrapQtApps = true;
+
+  buildInputs = [
+    qt6Packages.qtbase
+    qt6Packages.qtdeclarative
+  ];
+
+  meta = {
+    description = "Qt and QML MPRIS interface and adaptor";
+    homepage = "https://github.com/deepin-community/qt6mpris";
+    license = lib.licenses.lgpl21Plus;
+    platforms = lib.platforms.linux;
+    maintainers = lib.teams.deepin.members;
+  };
+})