From 98e983708328f7f51096ee61d6f70f3afe20a81e Mon Sep 17 00:00:00 2001
From: Anish Pallati <i@anish.land>
Date: Mon, 26 Jan 2026 03:39:07 -0500
Subject: [PATCH] tailscale-gui: init at 1.92.3

---
 pkgs/by-name/ta/tailscale-gui/package.nix | 51 +++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/ta/tailscale-gui/package.nix

diff --git a/pkgs/by-name/ta/tailscale-gui/package.nix b/pkgs/by-name/ta/tailscale-gui/package.nix
new file mode 100644
index 000000000000..214d6a6d3137
--- /dev/null
+++ b/pkgs/by-name/ta/tailscale-gui/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchurl,
+  xar,
+  cpio,
+  pbzx,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "tailscale-gui";
+  version = "1.92.3";
+
+  src = fetchurl {
+    url = "https://pkgs.tailscale.com/stable/Tailscale-${finalAttrs.version}-macos.pkg";
+    hash = "sha256-K5tJHyFhqnxV4KHzr7YOHRoH33vk+dq+EVWyUo88nuI=";
+  };
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [
+    xar
+    cpio
+    pbzx
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    xar -xf $src
+    cd Distribution.pkg
+    pbzx -n Payload | cpio -i
+
+    mkdir -p $out/Applications/Tailscale.app
+    mkdir -p $out/bin
+
+    cp -R Contents $out/Applications/Tailscale.app/
+    ln -s "$out/Applications/Tailscale.app/Contents/MacOS/Tailscale" "$out/bin/tailscale"
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Tailscale GUI client for macOS";
+    homepage = "https://tailscale.com";
+    changelog = "https://tailscale.com/changelog#client";
+    license = lib.licenses.unfree;
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    maintainers = with lib.maintainers; [ anish ];
+    platforms = lib.platforms.darwin;
+  };
+})