diff --git a/pkgs/by-name/fc/fcp/package.nix b/pkgs/by-name/fc/fcp/package.nix
new file mode 100644
index 000000000000..d3fb497b5a4f
--- /dev/null
+++ b/pkgs/by-name/fc/fcp/package.nix
@@ -0,0 +1,43 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  expect,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "fcp";
+  version = "0.2.2";
+
+  src = fetchFromGitHub {
+    owner = "svetlitski";
+    repo = "fcp";
+    tag = "v${finalAttrs.version}";
+    sha256 = "sha256-YupsJRtju9JyGGzSTk+tyEGh4ifpJllXVifsFoZ4Rwc=";
+  };
+
+  cargoHash = "sha256-PsYmzHwFpgAJ3AClt5buSuAtlXxvKQyz3XeZBtTXsLs=";
+
+  nativeBuildInputs = [ expect ];
+
+  # character_device fails with "File name too long" on darwin
+  doCheck = !stdenv.hostPlatform.isDarwin;
+
+  postPatch = ''
+    patchShebangs tests/*.exp
+  '';
+
+  meta = {
+    description = "Significantly faster alternative to the classic Unix cp(1) command";
+    homepage = "https://github.com/svetlitski/fcp";
+    changelog = "https://github.com/svetlitski/fcp/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.bsd3;
+    platforms = lib.platforms.unix;
+    maintainers = [
+      lib.maintainers.georgyo
+      lib.maintainers.flokli
+    ];
+    mainProgram = "fcp";
+  };
+})
diff --git a/pkgs/top-level/aliases.nix b/pkgs/top-level/aliases.nix
index fa2dd3bf642b..79f3d954d168 100644
--- a/pkgs/top-level/aliases.nix
+++ b/pkgs/top-level/aliases.nix
@@ -712,7 +712,6 @@ mapAliases {
   fcitx5-skk-qt = throw "'fcitx5-skk-qt' has been renamed to/replaced by 'qt6Packages.fcitx5-skk-qt'"; # Converted to throw 2025-10-27
   fcitx5-unikey = throw "'fcitx5-unikey' has been renamed to/replaced by 'qt6Packages.fcitx5-unikey'"; # Converted to throw 2025-10-27
   fcitx5-with-addons = throw "'fcitx5-with-addons' has been renamed to/replaced by 'qt6Packages.fcitx5-with-addons'"; # Converted to throw 2025-10-27
-  fcp = throw "'fcp' has been removed as it has been unmaintained upstream since August 2022"; # Added 2026-02-07
   fedifetcher = throw "'fedifetcher' has been removed because there is now a similar native feature in Mastodon."; # Added 2025-12-08
   fennel = throw "'fennel' has been renamed to/replaced by 'luaPackages.fennel'"; # Converted to throw 2025-10-27
   fetchbower = throw "fetchbower has been removed as bower was removed. It is recommended to migrate to yarn."; # Added 2025-09-17