From 0febaeb18bc96ddd0dc9334c4bd9de2739591c86 Mon Sep 17 00:00:00 2001
From: Sokhibjon Orzikulov <sakhib@orzklv.uz>
Date: Tue, 26 May 2026 19:03:08 +0500
Subject: [PATCH] gitte: init at 0.6.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

> Co-authored-by: Dyego Aurélio <dyegoaurelio@gmail.com>
---
 pkgs/by-name/gi/gitte/package.nix | 78 +++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 pkgs/by-name/gi/gitte/package.nix

diff --git a/pkgs/by-name/gi/gitte/package.nix b/pkgs/by-name/gi/gitte/package.nix
new file mode 100644
index 000000000000..bb81e9afeb2f
--- /dev/null
+++ b/pkgs/by-name/gi/gitte/package.nix
@@ -0,0 +1,78 @@
+{
+  lib,
+  stdenv,
+  fetchFromCodeberg,
+  nix-update-script,
+  meson,
+  ninja,
+  pkg-config,
+  rustPlatform,
+  cargo,
+  rustc,
+  wrapGAppsHook4,
+  desktop-file-utils,
+  appstream,
+  gettext,
+  glib,
+  gtk4,
+  libadwaita,
+  openssl,
+  libgit2,
+  zlib,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gitte";
+  version = "0.6.1";
+
+  __structuredAttrs = true;
+
+  src = fetchFromCodeberg {
+    owner = "ckruse";
+    repo = "Gitte";
+    tag = finalAttrs.version;
+    hash = "sha256-ieW/oOFdyJWVR/7B62Rzcyii+/zDj/Xp6KCrVOf6mpA=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-VhcJepTeEjA/ZogqR82Whlyz4NRuI5MLB2HqNjGe8zQ=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    rustPlatform.cargoSetupHook
+    cargo
+    rustc
+    wrapGAppsHook4
+    desktop-file-utils
+    appstream
+    gettext
+    glib
+  ];
+
+  buildInputs = [
+    gtk4
+    libadwaita
+    openssl
+    libgit2
+    zlib
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://codeberg.org/ckruse/Gitte";
+    mainProgram = "gitte";
+    description = "GTK4/libadwaita Git client";
+    license = with lib.licenses; [ agpl3Plus ];
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [
+      ckruse
+      orzklv
+    ];
+  };
+})