From 206d68e865a65419570a95d6ffa7a3287bf339c3 Mon Sep 17 00:00:00 2001
From: David Morgan <djm_uk@protonmail.com>
Date: Tue, 9 Jul 2024 08:57:29 +0000
Subject: [PATCH] wcurl: init at 2024.07.10

---
 pkgs/by-name/wc/wcurl/package.nix | 65 +++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/by-name/wc/wcurl/package.nix

diff --git a/pkgs/by-name/wc/wcurl/package.nix b/pkgs/by-name/wc/wcurl/package.nix
new file mode 100644
index 000000000000..381279883d0c
--- /dev/null
+++ b/pkgs/by-name/wc/wcurl/package.nix
@@ -0,0 +1,65 @@
+{
+  stdenvNoCC,
+  lib,
+  curl,
+  fetchFromGitLab,
+  installShellFiles,
+  nix-update-script,
+  shunit2,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "wcurl";
+  version = "2024.07.10";
+
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "debian";
+    repo = "wcurl";
+    rev = "refs/tags/${finalAttrs.version}";
+    hash = "sha256-FYkG74uoXFNYT7tszDcdCPQCEG3ePOFBUgIUYpsAzb8=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  nativeCheckInputs = [ shunit2 ];
+
+  doCheck = true;
+
+  dontBuild = true;
+
+  postPatch = ''
+    substituteInPlace wcurl \
+      --replace-fail '"curl "' '"${curl}/bin/curl "'
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+
+    tests/tests.sh
+
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    install -D wcurl -t $out/bin
+    installManPage wcurl.1
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://salsa.debian.org/debian/wcurl";
+    description = "Simple wrapper around curl to easily download files";
+    mainProgram = "wcurl";
+    license = lib.licenses.curl;
+    maintainers = with lib.maintainers; [ deejayem ];
+    platforms = lib.platforms.all;
+  };
+})