From c14eea4451fa6334c4171572c151b2cd4a8e97ab Mon Sep 17 00:00:00 2001
From: Simon Arlott <sa.me.uk>
Date: Wed, 18 Jun 2025 22:44:44 +0100
Subject: [PATCH 1/2] maintainer: add nomis

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 2e29fd89dc3d..12750d889ee3 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -18086,6 +18086,12 @@
     githubId = 148037;
     name = "Joachim Breitner";
   };
+  nomis = {
+    email = "nixpkgs@octiron.net";
+    github = "nomis";
+    githubId = 70171;
+    name = "Simon Arlott";
+  };
   nomisiv = {
     email = "simon@nomisiv.com";
     github = "NomisIV";

From ca596975ab053d6865e328ef7cbd9ac9789963fe Mon Sep 17 00:00:00 2001
From: Simon Arlott <sa.me.uk>
Date: Wed, 18 Jun 2025 22:48:31 +0100
Subject: [PATCH 2/2] dtee: init at 1.1.3

---
 pkgs/by-name/dt/dtee/package.nix | 91 ++++++++++++++++++++++++++++++++
 1 file changed, 91 insertions(+)
 create mode 100644 pkgs/by-name/dt/dtee/package.nix

diff --git a/pkgs/by-name/dt/dtee/package.nix b/pkgs/by-name/dt/dtee/package.nix
new file mode 100644
index 000000000000..b8b92a3b1ade
--- /dev/null
+++ b/pkgs/by-name/dt/dtee/package.nix
@@ -0,0 +1,91 @@
+{
+  fetchFromGitHub,
+  lib,
+  nix-update-script,
+  pkgs,
+  stdenv,
+  # nativeBuildInputs
+  gettext,
+  meson,
+  ninja,
+  pkg-config,
+  python3,
+  sphinx,
+  # buildInputs
+  boost,
+  # nativeCheckInputs
+  bash,
+  coreutils,
+  diffutils,
+  findutils,
+  glibcLocales,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dtee";
+  version = "1.1.3";
+
+  src = fetchFromGitHub {
+    owner = "nomis";
+    repo = "dtee";
+    tag = finalAttrs.version;
+    hash = "sha256-trREhITO3cY4j75mpudWhOA3GXI0Q8GkUxNq2s6154w=";
+  };
+
+  passthru.updateScript = nix-update-script { };
+
+  # Make "#!/usr/bin/env bash" work in tests
+  postPatch = "patchShebangs tests";
+
+  nativeBuildInputs = [
+    gettext
+    meson
+    ninja
+    pkg-config
+    python3
+    sphinx # For the man page
+  ];
+
+  buildInputs = [ boost ];
+
+  nativeCheckInputs = [
+    bash
+    coreutils
+    diffutils
+    findutils
+    glibcLocales # For tests that check translations work
+  ];
+
+  # Use the correct copyright year on the man page (workaround for https://github.com/sphinx-doc/sphinx/issues/13231)
+  preBuild = ''
+    SOURCE_DATE_EPOCH=$(python3 $NIX_BUILD_TOP/$sourceRoot/release_date.py -e ${finalAttrs.version}) || exit 1
+    export SOURCE_DATE_EPOCH
+  '';
+
+  mesonFlags = [ "--unity on" ];
+  doCheck = true;
+
+  meta = {
+    description = "Run a program with standard output and standard error copied to files";
+    longDescription = ''
+      Run a program with standard output and standard error copied to files
+      while maintaining the original standard output and standard error in
+      the original order. When invoked as "cronty", allows programs to be run
+      from cron, suppressing all output unless the process outputs an error
+      message or has a non-zero exit status whereupon the original output
+      will be written as normal and the exit code will be appended to standard
+      error.
+    '';
+
+    homepage = "https://dtee.readthedocs.io/";
+    downloadPage = "https://github.com/nomis/dtee/releases/tag/${finalAttrs.version}";
+    changelog = "https://dtee.readthedocs.io/en/${finalAttrs.version}/changelog.html";
+
+    license = lib.licenses.gpl3Plus;
+    sourceProvenance = [ lib.sourceTypes.fromSource ];
+    maintainers = with lib.maintainers; [ nomis ];
+    mainProgram = "dtee";
+    # Only Linux has reliable local datagram sockets
+    platforms = lib.platforms.linux;
+  };
+})