diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index ce9f65a92b5d..6e6d3182e9cb 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -26846,6 +26846,12 @@
     githubId = 367185;
     name = "Jan Votava";
   };
+  voxi0 = {
+    name = "Wasiq Arbab";
+    email = "alif200099@gmail.com";
+    github = "Voxi0";
+    githubId = 113725768;
+  };
   vpetersson = {
     email = "vpetersson@screenly.io";
     github = "vpetersson";
diff --git a/pkgs/by-name/wa/wayland-bongocat/package.nix b/pkgs/by-name/wa/wayland-bongocat/package.nix
new file mode 100644
index 000000000000..445ce3b0f879
--- /dev/null
+++ b/pkgs/by-name/wa/wayland-bongocat/package.nix
@@ -0,0 +1,57 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  wayland,
+  wayland-protocols,
+  wayland-scanner,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "wayland-bongocat";
+  version = "1.2.1";
+  src = fetchFromGitHub {
+    owner = "saatvik333";
+    repo = "wayland-bongocat";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-mtbw4UW5I2et2cVWrkCKWbG0p3tDGhgmHfH60OHvPkI=";
+  };
+
+  # Package dependencies
+  strictDeps = true;
+  nativeBuildInputs = [
+    pkg-config
+    wayland-scanner
+  ];
+  buildInputs = [
+    wayland
+    wayland-protocols
+  ];
+
+  # Build phases
+  # Ensure that the Makefile has the correct directory with the Wayland protocols
+  preBuild = ''
+    export WAYLAND_PROTOCOLS_DIR="${wayland-protocols}/share/wayland-protocols"
+  '';
+
+  makeFlags = [ "release" ];
+  installPhase = ''
+    runHook preInstall
+
+    # Install binaries
+    install -Dm755 build/bongocat $out/bin/${finalAttrs.meta.mainProgram}
+    install -Dm755 scripts/find_input_devices.sh $out/bin/bongocat-find-devices
+
+    runHook postInstall
+  '';
+
+  # Package information
+  meta = {
+    description = "Delightful Wayland overlay that displays an animated bongo cat reacting to keyboard input";
+    homepage = "https://github.com/saatvik333/wayland-bongocat";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ voxi0 ];
+    mainProgram = "bongocat";
+    platforms = lib.platforms.linux;
+  };
+})