From ccaa0205bcac5abc582645d94826164ddedd3b4f Mon Sep 17 00:00:00 2001
From: Gaetan Lepage <gaetan@glepage.com>
Date: Tue, 11 Nov 2025 14:19:11 +0000
Subject: [PATCH] typesetter: init at 0.5.0

---
 pkgs/by-name/ty/typesetter/package.nix | 85 ++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)
 create mode 100644 pkgs/by-name/ty/typesetter/package.nix

diff --git a/pkgs/by-name/ty/typesetter/package.nix b/pkgs/by-name/ty/typesetter/package.nix
new file mode 100644
index 000000000000..6325c3880b40
--- /dev/null
+++ b/pkgs/by-name/ty/typesetter/package.nix
@@ -0,0 +1,85 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitea,
+  rustPlatform,
+
+  # nativeBuildInputs
+  cargo,
+  desktop-file-utils,
+  gettext,
+  meson,
+  ninja,
+  pkg-config,
+  python3,
+  rustc,
+  wrapGAppsHook4,
+
+  # buildInputs
+  gdk-pixbuf,
+  graphene,
+  gtk4,
+  gtksourceview5,
+  libadwaita,
+  libspelling,
+  openssl,
+  pango,
+
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "typesetter";
+  version = "0.5.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "haydn";
+    repo = "typesetter";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-TYSmkjYvRUlKxilKr7WlUYQ2U/PsSuI/b8HOnUreXYk=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-lizLARb0wL3hHRl3kbxrlWyt0rB1BUuoZbaVIUeFMXU=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cargo
+    desktop-file-utils
+    gettext # msgfmt
+    meson
+    ninja
+    pkg-config
+    python3
+    rustPlatform.cargoSetupHook
+    rustc
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    gdk-pixbuf
+    graphene
+    gtk4
+    gtksourceview5
+    libadwaita
+    libspelling
+    openssl
+    pango
+  ];
+
+  env.OPENSSL_NO_VENDOR = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Minimalist, local-first Typst editor";
+    homepage = "https://codeberg.org/haydn/typesetter";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers; [ GaetanLepage ];
+    mainProgram = "typesetter";
+  };
+})