lib.types.functionTo: Support type merging

2022-05-13 08:59:27 +02:00
parent f771d39750
commit 06da97fc3a
3 changed files with 62 additions and 0 deletions
--- a/lib/tests/modules/functionTo/submodule-options.nix
+++ b/lib/tests/modules/functionTo/submodule-options.nix
@@ -0,0 +1,59 @@
+{ lib, config, options, ... }:
+let
+  inherit (lib) types;
+in
+{
+  imports = [
+
+    # fun.<function-body>.a
+    ({ ... }: {
+      options = {
+        fun = lib.mkOption {
+          type = types.functionTo (types.submodule {
+            options.a = lib.mkOption { };
+          });
+        };
+      };
+    })
+
+    # fun.<function-body>.b
+    ({ ... }: {
+      options = {
+        fun = lib.mkOption {
+          type = types.functionTo (types.submodule {
+            options.b = lib.mkOption { };
+          });
+        };
+      };
+    })
+  ];
+
+  options = {
+    result = lib.mkOption
+      {
+        type = types.str;
+        default = lib.concatStringsSep " "
+          (lib.concatLists
+            (lib.mapAttrsToList
+              (k: v:
+                if k == "_module"
+                then [ ]
+                else [ (lib.showOption v.loc) ]
+              )
+              (
+                (options.fun.type.getSubOptions [ "fun" ])
+              )
+            )
+          );
+      };
+  };
+
+  config.fun = lib.mkMerge
+    [
+      (input: { inherit (input) a; })
+      (input: { inherit (input) b; })
+      (input: {
+        b = lib.mkForce input.c;
+      })
+    ];
+}