From 3cf373b299655179c92cb2705b5b36ead1af480e Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Cl=C3=A9ment=20DOUIN?= <clement.douin@posteo.net>
Date: Sat, 15 Apr 2023 00:05:23 +0200
Subject: [PATCH] comodoro: init at 0.0.8

comodoro: move project to misc, bump v0.0.8

comodoro: fix comments

comodoro: fix typo
---
 pkgs/applications/misc/comodoro/default.nix | 47 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  2 +
 2 files changed, 49 insertions(+)
 create mode 100644 pkgs/applications/misc/comodoro/default.nix

diff --git a/pkgs/applications/misc/comodoro/default.nix b/pkgs/applications/misc/comodoro/default.nix
new file mode 100644
index 000000000000..c036b2aa2c7d
--- /dev/null
+++ b/pkgs/applications/misc/comodoro/default.nix
@@ -0,0 +1,47 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, stdenv
+, installShellFiles
+, installShellCompletions ? stdenv.hostPlatform == stdenv.buildPlatform
+, installManPages ? stdenv.hostPlatform == stdenv.buildPlatform
+, withTcp ? true
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "comodoro";
+  version = "0.0.8";
+
+  src = fetchFromGitHub {
+    owner = "soywod";
+    repo = "comodoro";
+    rev = "v${version}";
+    sha256 = "rGnVXyfWJkPHfpf1gRGbDJ6Y1ycKOOcCZ+Jx35fUo6M=";
+  };
+
+  cargoSha256 = "jpshuavywCLN03xD/gFgQeGbKtmHq5pULbxd+RUbaDk=";
+
+  nativeBuildInputs = lib.optional (installManPages || installShellCompletions) installShellFiles;
+
+  buildNoDefaultFeatures = true;
+  buildFeatures = lib.optional withTcp "tcp";
+
+  postInstall = lib.optionalString installManPages ''
+    mkdir -p $out/man
+    $out/bin/comodoro man $out/man
+    installManPage $out/man/*
+  '' + lib.optionalString installShellCompletions ''
+    installShellCompletion --cmd comodoro \
+      --bash <($out/bin/comodoro completion bash) \
+      --fish <($out/bin/comodoro completion fish) \
+      --zsh <($out/bin/comodoro completion zsh)
+  '';
+
+  meta = with lib; {
+    description = "CLI to manage your time.";
+    homepage = "https://pimalaya.org/comodoro/";
+    changelog = "https://github.com/soywod/comodoro/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ soywod ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index fa879730673d..720e0df53ade 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -479,6 +479,8 @@ with pkgs;
 
   commix = callPackage ../tools/security/commix { };
 
+  comodoro = callPackage ../applications/misc/comodoro { };
+
   compdb = callPackage ../tools/misc/compdb { };
 
   conserver = callPackage ../tools/misc/conserver { };