From 016a6cf6be6513889c41a35c90e5aef2559b499b Mon Sep 17 00:00:00 2001
From: Seth Flynn <getchoo@tuta.io>
Date: Wed, 14 May 2025 22:02:54 -0400
Subject: [PATCH] python312Packages.modern-colorthief: init at 0.1.7

---
 .../modern-colorthief/default.nix             | 60 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 62 insertions(+)
 create mode 100644 pkgs/development/python-modules/modern-colorthief/default.nix

diff --git a/pkgs/development/python-modules/modern-colorthief/default.nix b/pkgs/development/python-modules/modern-colorthief/default.nix
new file mode 100644
index 000000000000..52932819ae48
--- /dev/null
+++ b/pkgs/development/python-modules/modern-colorthief/default.nix
@@ -0,0 +1,60 @@
+{
+  lib,
+  buildPythonPackage,
+  colorthief,
+  fetchFromGitHub,
+  nix-update-script,
+  pillow,
+  pytestCheckHook,
+  rustPlatform,
+}:
+
+buildPythonPackage rec {
+  pname = "modern-colorthief";
+  version = "0.1.7";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "baseplate-admin";
+    repo = "modern_colorthief";
+    tag = version;
+    hash = "sha256-tALF9EIBTyVi3Ca4kQl9x+V12gjr0xH9OOmuoToxuJA=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit pname version src;
+    hash = "sha256-DldfoDpE7epb99Huq0RXkS3cAw0RtIzdWvr9OuZRZTI=";
+  };
+
+  nativeBuildInputs = [
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+  ];
+
+  optional-dependencies = {
+    test = [
+      colorthief
+      pillow
+    ];
+  };
+
+  nativeCheckInputs = [ pytestCheckHook ] ++ lib.attrValues optional-dependencies;
+
+  disabledTestPaths = [
+    # Requires `fast_colorthief`, which isn't packaged
+    "examples/test_time.py"
+  ];
+
+  pythonImportsCheck = [ "modern_colorthief" ];
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    homepage = "https://modern-colorthief.readthedocs.io/";
+    changelog = "https://github.com/baseplate-admin/modern_colorthief/releases/tag/${src.tag}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ getchoo ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 2d7487070cd8..bb1251370fcd 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -9059,6 +9059,8 @@ self: super: with self; {
 
   modeled = callPackage ../development/python-modules/modeled { };
 
+  modern-colorthief = callPackage ../development/python-modules/modern-colorthief { };
+
   moderngl = callPackage ../development/python-modules/moderngl { };
 
   moderngl-window = callPackage ../development/python-modules/moderngl-window { };